FEX-Emu/linux
1
0
Fork 0
mirror of https://github.com/FEX-Emu/linux.git synced 2024-12-14 04:41:26 +00:00
Code Issues Actions Packages Projects Releases Wiki Activity

coccinelle: api: add vma_pages.cocci

Browse Source 
This semantic patch replaces explicit computations of vma page count
with explicit function call.

Signed-off-by: Dmitry Kalinkin <dmitry.kalinkin@gmail.com>
Acked-by: Julia Lawall <julia.lawall@lip6.fr>
Signed-off-by: Michal Marek <mmarek@suse.cz>
This commit is contained in:
Dmitry Kalinkin 2015-05-21 19:19:13 +08:00 committed by Michal Marek
parent 74de120d80
commit 4c8f20bb8e
1 changed files with 60 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

60
scripts/coccinelle/api/vma_pages.cocci Normal file
View File

@ -0,0 +1,60 @@
///
/// Use vma_pages function on vma object instead of explicit computation.
///
// Confidence: High
// Keywords: vma_pages vma
// Comment: Based on resource_size.cocci
virtual context
virtual patch
virtual org
virtual report
//----------------------------------------------------------
// For context mode
//----------------------------------------------------------
@r_context depends on context && !patch && !org && !report@
struct vm_area_struct *vma;
@@
* (vma->vm_end - vma->vm_start) >> PAGE_SHIFT
//----------------------------------------------------------
// For patch mode
//----------------------------------------------------------
@r_patch depends on !context && patch && !org && !report@
struct vm_area_struct *vma;
@@
- ((vma->vm_end - vma->vm_start) >> PAGE_SHIFT)
+ vma_pages(vma)
//----------------------------------------------------------
// For org mode
//----------------------------------------------------------
@r_org depends on !context && !patch && (org || report)@
struct vm_area_struct *vma;
position p;
@@
(vma->vm_end@p - vma->vm_start) >> PAGE_SHIFT
@script:python depends on report@
p << r_org.p;
x << r_org.vma;
@@
msg="WARNING: Consider using vma_pages helper on %s" % (x)
coccilib.report.print_report(p[0], msg)
@script:python depends on org@
p << r_org.p;
x << r_org.vma;
@@
msg="WARNING: Consider using vma_pages helper on %s" % (x)
msg_safe=msg.replace("[","@(").replace("]",")")
coccilib.org.print_todo(p[0], msg_safe)