mirror of
https://github.com/FEX-Emu/linux.git
synced 2024-12-27 20:07:09 +00:00
f44f1e7da7
Building a statically linked UML kernel on a Centos 6.9 host resulted in
the following linking failure (GCC 4.4, glibc-2.12):
/usr/lib/gcc/x86_64-redhat-linux/4.4.7/../../../../lib64/libpthread.a(libpthread.o):
In function `siglongjmp':
(.text+0x8490): multiple definition of `longjmp'
arch/x86/um/built-in.o:/local/users/fainelli/openwrt/trunk/build_dir/target-x86_64_musl/linux-uml/linux-4.4.69/arch/x86/um/setjmp_64.S:44:
first defined here
/usr/lib/gcc/x86_64-redhat-linux/4.4.7/../../../../lib64/libpthread.a(libpthread.o):
In function `sem_open':
(.text+0x77cd): warning: the use of `mktemp' is dangerous, better use
`mkstemp'
collect2: ld returned 1 exit status
make[4]: *** [vmlinux] Error 1
Adopt a solution similar to the one done for vmap where we define
longjmp/setjmp to be kernel_longjmp/setjmp. In the process, make sure we
do rename the functions in arch/x86/um/setjmp_*.S accordingly.
Fixes: a7df4716d1 ("um: link with -lpthread")
Signed-off-by: Florian Fainelli <f.fainelli@gmail.com>
Signed-off-by: Richard Weinberger <richard@nod.at>
59 lines
1.0 KiB
ArmAsm
59 lines
1.0 KiB
ArmAsm
#
|
|
# arch/i386/setjmp.S
|
|
#
|
|
# setjmp/longjmp for the i386 architecture
|
|
#
|
|
|
|
#
|
|
# The jmp_buf is assumed to contain the following, in order:
|
|
# %ebx
|
|
# %esp
|
|
# %ebp
|
|
# %esi
|
|
# %edi
|
|
# <return address>
|
|
#
|
|
|
|
.text
|
|
.align 4
|
|
.globl kernel_setjmp
|
|
.type kernel_setjmp, @function
|
|
kernel_setjmp:
|
|
#ifdef _REGPARM
|
|
movl %eax,%edx
|
|
#else
|
|
movl 4(%esp),%edx
|
|
#endif
|
|
popl %ecx # Return address, and adjust the stack
|
|
xorl %eax,%eax # Return value
|
|
movl %ebx,(%edx)
|
|
movl %esp,4(%edx) # Post-return %esp!
|
|
pushl %ecx # Make the call/return stack happy
|
|
movl %ebp,8(%edx)
|
|
movl %esi,12(%edx)
|
|
movl %edi,16(%edx)
|
|
movl %ecx,20(%edx) # Return address
|
|
ret
|
|
|
|
.size kernel_setjmp,.-kernel_setjmp
|
|
|
|
.text
|
|
.align 4
|
|
.globl kernel_longjmp
|
|
.type kernel_longjmp, @function
|
|
kernel_longjmp:
|
|
#ifdef _REGPARM
|
|
xchgl %eax,%edx
|
|
#else
|
|
movl 4(%esp),%edx # jmp_ptr address
|
|
movl 8(%esp),%eax # Return value
|
|
#endif
|
|
movl (%edx),%ebx
|
|
movl 4(%edx),%esp
|
|
movl 8(%edx),%ebp
|
|
movl 12(%edx),%esi
|
|
movl 16(%edx),%edi
|
|
jmp *20(%edx)
|
|
|
|
.size kernel_longjmp,.-kernel_longjmp
|