gecko-dev/webtools/bonsai/configure.in

dnl Process this file with autoconf to produce a configure script.
AC_INIT
PERL_VERSION=5.006

dnl Checks for programs.
AC_PATH_PROGS(PERL, $PERL perl5 perl)
AC_MSG_CHECKING([for minimum required perl version >= $PERL_VERSION])
_perl_version=`PERL_VERSION=$PERL_VERSION $PERL -e 'print "$]"; if ($] >= $ENV{PERL_VERSION}) { exit(0); } else { exit(1); }' 2>&5`
_perl_res=$?
AC_MSG_RESULT([$_perl_version])

if test "$_perl_res" != 0; then
    AC_MSG_ERROR([Perl $PERL_VERSION or higher is required.])
fi

AC_MSG_CHECKING([for full perl installation])
_perl_archlib=`$PERL -e 'use Config; if ( -d $Config{archlib} ) { exit(0); } else { exit(1); }' 2>&5`
_perl_res=$?
if test "$_perl_res" != 0; then
    AC_MSG_RESULT([no])
    AC_MSG_ERROR([Cannot find Config.pm or \$Config{archlib}.  A full perl installation is required.])
else
    AC_MSG_RESULT([yes])    
fi

AC_PATH_PROG(CO, co)
AC_PATH_PROG(CVS, cvs)
AC_PATH_PROG(CVSGRAPH, cvsgraph)
AC_PATH_PROG(RLOG, rlog)
AC_PATH_PROG(RCSDIFF, rcsdiff)

if test -z "$CO" -o -z "$CVS" -o -z "$RLOG" -o -z "$RCSDIFF"; then
   AC_MSG_ERROR([Missing one or more required binaries.])
fi


dnl Checks for libraries.

dnl Checks for header files.

dnl Checks for typedefs, structures, and compiler characteristics.

dnl Checks for library functions.
AC_CHECK_PERL_MODULES([ \
	CGI::Carp \
	DBD::mysql \
	DBI \
	Date::Format \
	Date::Parse \
	File::Basename \
	File::Path \
	Mail::Internet \
	Mail::Mailer \
	Time::Local \
],,_missing_perl_mod=1)

if test -n "$_missing_perl_mod"; then
   AC_MSG_ERROR([Missing one or more required Perl modules.])
fi

AC_OUTPUT(Makefile)
AC_OUTPUT_COMMANDS([echo type 'make install' to install bonsai])