Magic-Mirror/llvm-capstone
1
0
Fork 0
mirror of https://github.com/capstone-engine/llvm-capstone.git synced 2024-11-23 13:50:11 +00:00
Code Issues Actions 2 Packages Projects Releases Wiki Activity
a45d2287ad
llvm-capstone/runtimes/CMakeLists.txt

Ignoring revisions in .git-blame-ignore-revs. Click here to bypass and see the normal blame view.

242 lines
8.8 KiB
CMake
Raw Normal View History

[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
# This file handles building LLVM runtime sub-projects.
cmake_minimum_required(VERSION 3.13.4)
project(Runtimes C CXX ASM)
[runtimes] Add the libc project to the list of runtimes. This is possible as the default libc build now works under runtimes build. Differential Revision: https://reviews.llvm.org/D99101
2021-03-22 18:59:49 +00:00
set(LLVM_ALL_RUNTIMES "compiler-rt;libc;libcxx;libcxxabi;libunwind;openmp")
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
set(LLVM_ENABLE_RUNTIMES "" CACHE STRING
"Semicolon-separated list of runtimes to build (${LLVM_ALL_RUNTIMES}), or \"all\".")
if(LLVM_ENABLE_RUNTIMES STREQUAL "all" )
set(LLVM_ENABLE_RUNTIMES ${LLVM_ALL_RUNTIMES})
endif()
foreach(proj ${LLVM_ENABLE_RUNTIMES})
set(proj_dir "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
if(IS_DIRECTORY ${proj_dir} AND EXISTS ${proj_dir}/CMakeLists.txt)
list(APPEND runtimes ${proj_dir})
else()
message(FATAL_ERROR "LLVM_ENABLE_RUNTIMES requests ${proj} but directory not found: ${proj_dir}")
endif()
string(TOUPPER "${proj}" canon_name)
STRING(REGEX REPLACE "-" "_" canon_name ${canon_name})
set(LLVM_EXTERNAL_${canon_name}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../${proj}")
endforeach()
function(runtime_register_component name)
set_property(GLOBAL APPEND PROPERTY SUB_COMPONENTS ${name})
endfunction()
find_package(LLVM PATHS "${LLVM_BINARY_DIR}" NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
find_package(Clang PATHS "${LLVM_BINARY_DIR}" NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
# Add path for custom and the LLVM build's modules to the CMake module path.
list(INSERT CMAKE_MODULE_PATH 0
"${CMAKE_CURRENT_SOURCE_DIR}/cmake"
"${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
"${CMAKE_CURRENT_SOURCE_DIR}/../llvm/cmake"
"${CMAKE_CURRENT_SOURCE_DIR}/../llvm/cmake/modules"
)
Reland "[benchmarks] Move libcxx's fork of google/benchmark and llvm/utils'"" This reverts commit e7568b68da8a216dc22cdc1c6d8903c94096c846 and relands c6f7b720ecfa6db40c648eb05e319f8a817110e9. The culprit was: missed that libc also had a dependency on one of the copies of `google-benchmark` Also opportunistically fixed indentation from prev. change. Differential Revision: https://reviews.llvm.org/D112012
2021-11-16 17:44:26 +00:00
set(LLVM_THIRD_PARTY_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../third-party")
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
function(get_compiler_rt_path path)
foreach(entry ${runtimes})
get_filename_component(projName ${entry} NAME)
if("${projName}" MATCHES "compiler-rt")
set(${path} ${entry} PARENT_SCOPE)
return()
endif()
endforeach()
endfunction()
# Some of the runtimes will conditionally use the compiler-rt sanitizers
# to make this work smoothly we ensure that compiler-rt is added first in
# the list of sub-projects. This allows other sub-projects to have checks
# like `if(TARGET asan)` to enable building with asan.
get_compiler_rt_path(compiler_rt_path)
if(compiler_rt_path)
list(REMOVE_ITEM runtimes ${compiler_rt_path})
if(NOT DEFINED LLVM_BUILD_COMPILER_RT OR LLVM_BUILD_COMPILER_RT)
list(INSERT runtimes 0 ${compiler_rt_path})
endif()
endif()
Reapply [runtimes] Set more paths when building runtimes standalone These paths are needed when building with per-target runtime directories. (It's possible to fix this by manually setting these when invoking cmake, but one isn't supposed to need to do that.) Also set LLVM_TOOLS_BINARY_DIR while touching this area (as it's also unset in this case) even if it isn't specifically needed by the per-target runtime configuration. Fixed since previous attempt: Don't check if the runtimes directory is the root of the CMake invocation; when the main LLVM CMake build builds runtimes, it does invoke a sub-CMake with this directory as the root too, just as if manually invoking CMake at the runtimes directory. Instead check whether LLVM_TOOLS_BINARY_DIR was set and whether find_package(LLVM) succeeded or not. Differential Revision: https://reviews.llvm.org/D107895
2021-08-11 11:14:31 +00:00
# If building standalone by pointing CMake at this runtimes directory,
# LLVM_BINARY_DIR isn't set, find_package(LLVM) will fail and these
# intermediate paths are unset.
[CMake] Use NOT instead of STREQUAL `<var> STREQUAL ""` fails when `<var>` is unset which can be the case when using runtimes as top-level build. Use `NOT` instead. Differential Revision: https://reviews.llvm.org/D109570
2021-09-10 07:07:07 +00:00
if (NOT LLVM_BINARY_DIR)
Reapply [runtimes] Set more paths when building runtimes standalone These paths are needed when building with per-target runtime directories. (It's possible to fix this by manually setting these when invoking cmake, but one isn't supposed to need to do that.) Also set LLVM_TOOLS_BINARY_DIR while touching this area (as it's also unset in this case) even if it isn't specifically needed by the per-target runtime configuration. Fixed since previous attempt: Don't check if the runtimes directory is the root of the CMake invocation; when the main LLVM CMake build builds runtimes, it does invoke a sub-CMake with this directory as the root too, just as if manually invoking CMake at the runtimes directory. Instead check whether LLVM_TOOLS_BINARY_DIR was set and whether find_package(LLVM) succeeded or not. Differential Revision: https://reviews.llvm.org/D107895
2021-08-11 11:14:31 +00:00
set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
endif()
if (NOT LLVM_FOUND)
set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
set(LLVM_LIBRARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/lib)
endif()
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
# Setting these variables will allow the sub-build to put their outputs into
# the library and bin directories of the top-level build.
set(LLVM_LIBRARY_OUTPUT_INTDIR ${LLVM_LIBRARY_DIR})
set(LLVM_RUNTIME_OUTPUT_INTDIR ${LLVM_TOOLS_BINARY_DIR})
# This variable makes sure that e.g. llvm-lit is found.
[runtimes] Calculate the path to the llvm directory without the LLVM cmake package If building by pointing cmake directly at the llvm-project/runtimes directory, the llvm cmake package files (that provide e.g. LLVM_BUILD_MAIN_SRC_DIR) aren't necessarily available. Instead just use a path relative to the current source dir. Differential Revision: https://reviews.llvm.org/D109717
2021-09-13 19:27:44 +00:00
set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../llvm)
[LLVM][CMake][NFC] Resolve FIXME: Rename LLVM_CMAKE_PATH to LLVM_CMAKE_DIR throughout the project This way, we do not need to set LLVM_CMAKE_PATH to LLVM_CMAKE_DIR when (NOT LLVM_CONFIG_FOUND) Reviewed By: #libc, ldionne Differential Revision: https://reviews.llvm.org/D107717
2021-09-16 16:27:53 +00:00
set(LLVM_CMAKE_DIR ${LLVM_MAIN_SRC_DIR}/cmake/modules)
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
# This variable is used by individual runtimes to locate LLVM files.
[runtimes] Calculate the path to the llvm directory without the LLVM cmake package If building by pointing cmake directly at the llvm-project/runtimes directory, the llvm cmake package files (that provide e.g. LLVM_BUILD_MAIN_SRC_DIR) aren't necessarily available. Instead just use a path relative to the current source dir. Differential Revision: https://reviews.llvm.org/D109717
2021-09-13 19:27:44 +00:00
set(LLVM_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../llvm)
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
if(APPLE)
set(LLVM_ENABLE_LIBCXX ON CACHE BOOL "")
endif()
include(CheckLibraryExists)
include(CheckCCompilerFlag)
[runtimes] Check whether -nostdinc++ and -nostdlib++ are supported Don't blindly assume they're supported - GCC doesn't support -nostdlib++. The llvm-project/runtimes directory is supposed to allow building the runtimes standalone from a newly built Clang, and thus should allow building with other compilers too. Differential Revision: https://reviews.llvm.org/D109719
2021-09-13 20:05:23 +00:00
include(CheckCXXCompilerFlag)
# Disable use of the installed C++ standard library when building runtimes.
# Check for -nostdlib++ first; if there's no C++ standard library yet,
# all check_cxx_compiler_flag commands will fail until we add -nostdlib++
# (or -nodefaultlibs).
check_c_compiler_flag(-nostdlib++ LLVM_RUNTIMES_SUPPORT_NOSTDLIBXX_FLAG)
if (LLVM_RUNTIMES_SUPPORT_NOSTDLIBXX_FLAG)
set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nostdlib++")
endif()
check_cxx_compiler_flag(-nostdinc++ LLVM_RUNTIMES_SUPPORT_NOSTDINCXX_FLAG)
if (LLVM_RUNTIMES_SUPPORT_NOSTDINCXX_FLAG)
set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -nostdinc++")
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
endif()
# Avoid checking whether the compiler is working.
set(LLVM_COMPILER_CHECKED ON)
# Handle common options used by all runtimes.
include(AddLLVM)
include(HandleLLVMOptions)
[runtimes] Use standalone build only for compiler-rt compiler-rt needs to use standalone build because of the assumptions made by its build, but other runtimes can use non-standalone build. Differential Revision: https://reviews.llvm.org/D97575
2021-02-26 20:52:53 +00:00
find_package(Python3 REQUIRED COMPONENTS Interpreter)
Revert "[runtimes] Use standalone build only for compiler-rt" This reverts commit 4e421b2323b38e94e82ac71e5a4dfd78f6744e87 as this seemed to have broke Python 3 executable detection on some builders.
2021-03-03 00:59:32 +00:00
[libcxxabi/runtimes] Set LLVM_HOST_TRIPLE in runtimes build This allows tests to tell if they're running natively. Those tests are libcxxabi/test/native/arm-linux-eabi. Which were running on Linaro's bots but became unsupported when we switched to the runtimes build. Reviewed By: #libc_abi, phosek Differential Revision: https://reviews.llvm.org/D113663
2021-11-11 12:28:39 +00:00
# Host triple is used by tests to check if they are running natively.
include(GetHostTriple)
get_host_triple(LLVM_HOST_TRIPLE)
set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
"Default target for which LLVM will generate code.")
[runtimes] Initialize LLVM_DEFAULT_TARGET_TRIPLE if not set by the caller Differential Revision: https://reviews.llvm.org/D109716
2021-09-13 19:27:17 +00:00
[libcxx] Add a CI configuration for standalone building in llvm-project/runtimes Generate the llvm-lit script in runtimes/CmakeFiles.txt unless invoked from llvm/runtimes. Differential Revision: https://reviews.llvm.org/D109593
2021-09-10 11:36:13 +00:00
option(LLVM_INCLUDE_TESTS "Generate build targets for the runtimes unit tests." ON)
[runtimes] Use the new "runtimes" build by default and deprecate other builds This commit makes the new "runtimes" build (with <monorepo>/runtimes as the root of the CMake invocation) the default way of building libc++. The other supported way of building libc++ is the "bootstrapping" build, where `<monorepo>/llvm` is used as the root of the CMake invocation. All other ways of building libc++ are deprecated effective immediately. There should be no use-case for building libc++ that isn't supported by one of these two builds, and the two new builds work on all environments and are lightweight. They will also make it possible to greatly simplify the build infrastructure of the runtimes, which is currently way too convoluted. Differential Revision: https://reviews.llvm.org/D111356
2021-10-07 20:19:11 +00:00
option(LLVM_INCLUDE_DOCS "Generate build targets for the runtimes documentation." ON)
option(LLVM_ENABLE_SPHINX "Use Sphinx to generate the runtimes documentation." OFF)
[libcxx] Add a CI configuration for standalone building in llvm-project/runtimes Generate the llvm-lit script in runtimes/CmakeFiles.txt unless invoked from llvm/runtimes. Differential Revision: https://reviews.llvm.org/D109593
2021-09-10 11:36:13 +00:00
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
# Use libtool instead of ar if you are both on an Apple host, and targeting Apple.
if(CMAKE_HOST_APPLE AND APPLE)
include(UseLibtool)
endif()
# This can be used to detect whether we're in the runtimes build.
[CMake] Rename RUNTIMES_BUILD to LLVM_RUNTIMES_BUILD This avoid potential conflict with other internal variables. Differential Revision: https://reviews.llvm.org/D97838
2021-03-03 08:39:50 +00:00
set(LLVM_RUNTIMES_BUILD ON)
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
foreach(entry ${runtimes})
get_filename_component(projName ${entry} NAME)
# TODO: Clean this up as part of an interface standardization
string(REPLACE "-" "_" canon_name ${projName})
string(TOUPPER ${canon_name} canon_name)
[runtimes] Use standalone build only for compiler-rt compiler-rt needs to use standalone build because of the assumptions made by its build, but other runtimes can use non-standalone build. Differential Revision: https://reviews.llvm.org/D97575
2021-02-26 20:52:53 +00:00
# TODO: compiler-rt has to use standalone build for now. We tried to remove
# this in D57992 but this broke the build because compiler-rt assumes that
# LLVM and Clang are configured in the same build to set up dependencies. We
# should clean up the compiler-rt build and remove this eventually.
if ("${canon_name}" STREQUAL "COMPILER_RT")
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
set(${canon_name}_STANDALONE_BUILD ON)
endif()
if(LLVM_RUNTIMES_LIBDIR_SUBDIR)
set(${canon_name}_LIBDIR_SUBDIR "${LLVM_RUNTIMES_LIBDIR_SUBDIR}" CACHE STRING "" FORCE)
endif()
# Setting a variable to let sub-projects detect which other projects
# will be included under here.
set(HAVE_${canon_name} ON)
endforeach()
[runtimes] Make sure LLVM_LIT_ARGS is set before including individual runtimes Otherwise, the individual `check-cxx`, `check-cxxabi` and similar targets will not know about `LLVM_LIT_ARGS`, and we'll end up running lit without any argument. Differential Revision: https://reviews.llvm.org/D112035
2021-10-18 21:54:05 +00:00
if(LLVM_INCLUDE_TESTS)
set(LIT_ARGS_DEFAULT "-sv --show-xfail --show-unsupported")
if (MSVC OR XCODE)
set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
endif()
set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
endif()
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
# We do this in two loops so that HAVE_* is set for each runtime before the
# other runtimes are added.
foreach(entry ${runtimes})
get_filename_component(projName ${entry} NAME)
# Between each sub-project we want to cache and clear the LIT properties
set_property(GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
set_property(GLOBAL PROPERTY LLVM_LIT_PARAMS)
set_property(GLOBAL PROPERTY LLVM_LIT_DEPENDS)
set_property(GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
add_subdirectory(${entry} ${projName})
get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
list(APPEND RUNTIMES_LIT_TESTSUITES ${LLVM_LIT_TESTSUITES})
list(APPEND RUNTIMES_LIT_PARAMS ${LLVM_LIT_PARAMS})
list(APPEND RUNTIMES_LIT_DEPENDS ${LLVM_LIT_DEPENDS})
list(APPEND RUNTIMES_LIT_EXTRA_ARGS ${LLVM_LIT_EXTRA_ARGS})
endforeach()
if(LLVM_INCLUDE_TESTS)
# Add a global check rule now that all subdirectories have been traversed
# and we know the total set of lit testsuites.
add_lit_target(check-runtimes
"Running all regression tests"
${RUNTIMES_LIT_TESTSUITES}
PARAMS ${RUNTIMES_LIT_PARAMS}
DEPENDS ${RUNTIMES_LIT_DEPENDS}
ARGS ${RUNTIMES_LIT_EXTRA_ARGS}
)
add_custom_target(runtimes-test-depends DEPENDS ${RUNTIMES_LIT_DEPENDS})
[libcxx] Add a CI configuration for standalone building in llvm-project/runtimes Generate the llvm-lit script in runtimes/CmakeFiles.txt unless invoked from llvm/runtimes. Differential Revision: https://reviews.llvm.org/D109593
2021-09-10 11:36:13 +00:00
if (NOT HAVE_LLVM_LIT)
# If built by manually invoking cmake on this directory, we don't have
# llvm-lit. If invoked via llvm/runtimes, the toplevel llvm cmake
# invocation already generated the llvm-lit script.
add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit
${CMAKE_CURRENT_BINARY_DIR}/llvm-lit)
endif()
[CMake] Split the target side of runtimes build Previously, llvm/runtimes/CMakeLists.txt played two different roles: 1. host side which could used to set up the build of runtimes for different targets in the right order; 2. target side to build the runtimes for the specified target. This change splits llvm/runtimes/CMakeLists.txt and moves the target side to runtimes/CMakeLists laying down the foundation for the "A vision for building the runtimes" proposal. From the user perspective, there shouldn't be any visible difference at the moment. Differential Revision: https://reviews.llvm.org/D93408
2020-12-16 18:26:42 +00:00
endif()
get_property(SUB_COMPONENTS GLOBAL PROPERTY SUB_COMPONENTS)
if(SUB_COMPONENTS)
list(REMOVE_DUPLICATES SUB_COMPONENTS)
foreach(component ${SUB_COMPONENTS})
if(NOT TARGET ${component})
message(SEND_ERROR "Missing target for runtime component ${component}!")
continue()
endif()
if(TARGET check-${component})
list(APPEND SUB_CHECK_TARGETS check-${component})
endif()
if(TARGET install-${component})
list(APPEND SUB_INSTALL_TARGETS install-${component})
endif()
if(TARGET install-${component}-stripped)
list(APPEND SUB_INSTALL_TARGETS install-${component}-stripped)
endif()
endforeach()
if(LLVM_RUNTIMES_TARGET)
configure_file(
${CMAKE_CURRENT_SOURCE_DIR}/Components.cmake.in
${LLVM_BINARY_DIR}/runtimes/${LLVM_RUNTIMES_TARGET}/Components.cmake)
else()
configure_file(
${CMAKE_CURRENT_SOURCE_DIR}/Components.cmake.in
${LLVM_BINARY_DIR}/runtimes/Components.cmake)
endif()
endif()
Reference in New Issue Copy Permalink