mirror of
https://github.com/capstone-engine/llvm-capstone.git
synced 2025-03-04 08:27:50 +00:00
1e03c37b97
This is a second attempt at D101497, which landed as
9a9bc76c0eb72f0f2732c729a460abbd5239c2e3 but had to be reverted in
8cf7ddbdd4e5af966a369e170c73250f2e3920e7.
This issue was that in the case that `COMPILER_RT_INSTALL_PATH` is
empty, expressions like "${COMPILER_RT_INSTALL_PATH}/bin" evaluated to
"/bin" not "bin" as intended and as was originally.
One solution is to make `COMPILER_RT_INSTALL_PATH` always non-empty,
defaulting it to `CMAKE_INSTALL_PREFIX`. D99636 adopted that approach.
But, I think it is more ergonomic to allow those project-specific paths
to be relative the global ones. Also, making install paths absolute by
default inhibits the proper behavior of functions like
`GNUInstallDirs_get_absolute_install_dir` which make relative install
paths absolute in a more complicated way.
Given all this, I will define a function like the one asked for in
https://gitlab.kitware.com/cmake/cmake/-/issues/19568 (and needed for a
similar use-case).
---
Original message:
Instead of using `COMPILER_RT_INSTALL_PATH` through the CMake for
complier-rt, just use it to define variables for the subdirs which
themselves are used.
This preserves compatibility, but later on we might consider getting rid
of `COMPILER_RT_INSTALL_PATH` and just changing the defaults for the
subdir variables directly.
---
There was a seaming bug where the (non-Apple) per-target libdir was
`${target}` not `lib/${target}`. I suspect that has to do with the docs
on `COMPILER_RT_INSTALL_PATH` saying was the library dir when that's no
longer true, so I just went ahead and fixed it, allowing me to define
fewer and more sensible variables.
That last part should be the only behavior changes; everything else
should be a pure refactoring.
---
I added some documentation of these variables too. In particular, I
wanted to highlight the gotcha where `-DSomeCachePath=...` without the
`:PATH` will lead CMake to make the path absolute. See [1] for
discussion of the problem, and [2] for the brief official documentation
they added as a result.
[1]: https://cmake.org/pipermail/cmake/2015-March/060204.html
[2]: https://cmake.org/cmake/help/latest/manual/cmake.1.html#options
In 38b2dec37ee735d5409148e71ecba278caf0f969 the problem was somewhat
misidentified and so `:STRING` was used, but `:PATH` is better as it
sets the correct type from the get-go.
---
D99484 is the main thrust of the `GnuInstallDirs` work. Once this lands,
it should be feasible to follow both of these up with a simple patch for
compiler-rt analogous to the one for libcxx.
Reviewed By: phosek, #libc_abi, #libunwind
Differential Revision: https://reviews.llvm.org/D105765
169 lines
6.7 KiB
CMake
169 lines
6.7 KiB
CMake
# TODO: Set the install directory.
|
|
|
|
include(ExternalProject)
|
|
|
|
set(known_subdirs
|
|
"libcxx"
|
|
)
|
|
|
|
foreach (dir ${known_subdirs})
|
|
if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${dir}/CMakeLists.txt)
|
|
add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${dir})
|
|
endif()
|
|
endforeach()
|
|
|
|
function(get_ext_project_build_command out_var target)
|
|
if (CMAKE_GENERATOR MATCHES "Make")
|
|
# Use special command for Makefiles to support parallelism.
|
|
set(${out_var} "$(MAKE)" "${target}" PARENT_SCOPE)
|
|
else()
|
|
set(${out_var} ${CMAKE_COMMAND} --build . --target ${target}
|
|
--config $<CONFIG> PARENT_SCOPE)
|
|
endif()
|
|
endfunction()
|
|
|
|
set(COMPILER_RT_SRC_ROOT ${LLVM_MAIN_SRC_DIR}/projects/compiler-rt)
|
|
# Fallback to the external path, if the other one isn't available.
|
|
# This is the same behavior (try "internal", then check the LLVM_EXTERNAL_...
|
|
# variable) as in add_llvm_external_project
|
|
if(NOT EXISTS ${COMPILER_RT_SRC_ROOT})
|
|
# We don't want to set it if LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR is ""
|
|
if(LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR)
|
|
set(COMPILER_RT_SRC_ROOT ${LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR})
|
|
endif()
|
|
endif()
|
|
|
|
if(LLVM_BUILD_EXTERNAL_COMPILER_RT AND EXISTS ${COMPILER_RT_SRC_ROOT}/)
|
|
|
|
# Add compiler-rt as an external project.
|
|
set(COMPILER_RT_PREFIX ${CMAKE_BINARY_DIR}/projects/compiler-rt)
|
|
|
|
set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/compiler-rt-stamps/)
|
|
set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/compiler-rt-bins/)
|
|
|
|
add_custom_target(compiler-rt-clear
|
|
COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
|
|
COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
|
|
COMMENT "Clobberring compiler-rt build and stamp directories"
|
|
)
|
|
|
|
# Find all variables that start with COMPILER_RT and populate a variable with
|
|
# them.
|
|
get_cmake_property(variableNames VARIABLES)
|
|
foreach(variableName ${variableNames})
|
|
if(variableName MATCHES "^COMPILER_RT")
|
|
string(REPLACE ";" "\;" value "${${variableName}}")
|
|
list(APPEND COMPILER_RT_PASSTHROUGH_VARIABLES
|
|
-D${variableName}=${value})
|
|
endif()
|
|
endforeach()
|
|
|
|
set(compiler_rt_configure_deps)
|
|
if(TARGET cxx-headers)
|
|
list(APPEND compiler_rt_configure_deps "cxx-headers")
|
|
endif()
|
|
if(LLVM_INCLUDE_TESTS)
|
|
list(APPEND compiler_rt_configure_deps LLVMTestingSupport)
|
|
endif()
|
|
|
|
ExternalProject_Add(compiler-rt
|
|
DEPENDS llvm-config clang ${compiler_rt_configure_deps}
|
|
PREFIX ${COMPILER_RT_PREFIX}
|
|
SOURCE_DIR ${COMPILER_RT_SRC_ROOT}
|
|
STAMP_DIR ${STAMP_DIR}
|
|
BINARY_DIR ${BINARY_DIR}
|
|
CMAKE_ARGS ${CLANG_COMPILER_RT_CMAKE_ARGS}
|
|
-DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
|
|
-DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++
|
|
-DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
|
|
-DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
|
|
-DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
|
|
-DLLVM_CONFIG_PATH=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-config
|
|
-DLLVM_LIT_ARGS=${LLVM_LIT_ARGS}
|
|
-DCOMPILER_RT_OUTPUT_DIR=${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION}
|
|
-DCOMPILER_RT_EXEC_OUTPUT_DIR=${LLVM_RUNTIME_OUTPUT_INTDIR}
|
|
-DCOMPILER_RT_INSTALL_PATH:PATH=lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION}
|
|
-DCOMPILER_RT_INCLUDE_TESTS=${LLVM_INCLUDE_TESTS}
|
|
-DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
|
|
-DLLVM_LIBDIR_SUFFIX=${LLVM_LIBDIR_SUFFIX}
|
|
-DLLVM_RUNTIME_OUTPUT_INTDIR=${LLVM_RUNTIME_OUTPUT_INTDIR}
|
|
-DCMAKE_OSX_DEPLOYMENT_TARGET=${CMAKE_OSX_DEPLOYMENT_TARGET}
|
|
-DCMAKE_OSX_SYSROOT:PATH=${CMAKE_OSX_SYSROOT}
|
|
${COMPILER_RT_PASSTHROUGH_VARIABLES}
|
|
INSTALL_COMMAND ""
|
|
STEP_TARGETS configure build
|
|
USES_TERMINAL_CONFIGURE 1
|
|
USES_TERMINAL_BUILD 1
|
|
USES_TERMINAL_INSTALL 1
|
|
# Always run the build command so that incremental builds are correct.
|
|
BUILD_ALWAYS 1
|
|
)
|
|
|
|
get_ext_project_build_command(run_clean_compiler_rt clean)
|
|
ExternalProject_Add_Step(compiler-rt clean
|
|
COMMAND ${run_clean_compiler_rt}
|
|
COMMENT "Cleaning compiler-rt..."
|
|
DEPENDEES configure
|
|
DEPENDERS build
|
|
DEPENDS clang
|
|
WORKING_DIRECTORY ${BINARY_DIR}
|
|
)
|
|
|
|
install(CODE "execute_process\(COMMAND \${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=\${CMAKE_INSTALL_PREFIX} -P ${BINARY_DIR}/cmake_install.cmake \)"
|
|
COMPONENT compiler-rt)
|
|
|
|
add_llvm_install_targets(install-compiler-rt
|
|
DEPENDS compiler-rt
|
|
COMPONENT compiler-rt)
|
|
|
|
# Add top-level targets that build specific compiler-rt runtimes.
|
|
set(COMPILER_RT_RUNTIMES fuzzer asan builtins dfsan lsan msan profile tsan ubsan ubsan-minimal)
|
|
foreach(runtime ${COMPILER_RT_RUNTIMES})
|
|
get_ext_project_build_command(build_runtime_cmd ${runtime})
|
|
add_custom_target(${runtime}
|
|
COMMAND ${build_runtime_cmd}
|
|
DEPENDS compiler-rt-configure
|
|
WORKING_DIRECTORY ${BINARY_DIR}
|
|
VERBATIM USES_TERMINAL)
|
|
endforeach()
|
|
|
|
if(LLVM_INCLUDE_TESTS)
|
|
# Add binaries that compiler-rt tests depend on.
|
|
set(COMPILER_RT_TEST_DEPENDENCIES
|
|
FileCheck count not llvm-nm llvm-objdump llvm-symbolizer)
|
|
|
|
# Add top-level targets for various compiler-rt test suites.
|
|
set(COMPILER_RT_TEST_SUITES check-fuzzer check-asan check-hwasan check-asan-dynamic check-dfsan
|
|
check-lsan check-msan check-sanitizer check-tsan check-ubsan check-ubsan-minimal
|
|
check-profile check-cfi check-cfi-and-supported check-safestack check-gwp_asan)
|
|
foreach(test_suite ${COMPILER_RT_TEST_SUITES})
|
|
get_ext_project_build_command(run_test_suite ${test_suite})
|
|
add_custom_target(${test_suite}
|
|
COMMAND ${run_test_suite}
|
|
DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
|
|
WORKING_DIRECTORY ${BINARY_DIR}
|
|
VERBATIM
|
|
USES_TERMINAL
|
|
)
|
|
endforeach()
|
|
|
|
# Add special target to run all compiler-rt test suites.
|
|
get_ext_project_build_command(run_check_compiler_rt check-all)
|
|
add_custom_target(check-compiler-rt
|
|
COMMAND ${run_check_compiler_rt}
|
|
DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
|
|
WORKING_DIRECTORY ${BINARY_DIR}
|
|
VERBATIM USES_TERMINAL)
|
|
|
|
# Add special target to run all compiler-rt test suites.
|
|
get_ext_project_build_command(run_check_compiler_rt compiler-rt-test-depends)
|
|
add_custom_target(compiler-rt-test-depends
|
|
COMMAND ${run_check_compiler_rt}
|
|
DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
|
|
WORKING_DIRECTORY ${BINARY_DIR}
|
|
VERBATIM USES_TERMINAL)
|
|
set_property(GLOBAL APPEND PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS compiler-rt-test-depends)
|
|
set_property(GLOBAL APPEND PROPERTY LLVM_ADDITIONAL_TEST_TARGETS check-compiler-rt)
|
|
endif()
|
|
endif()
|