mirror of
https://github.com/capstone-engine/llvm-capstone.git
synced 2024-12-27 10:18:36 +00:00
44e3365775
See the docs in the new function for details. I think I found every instance of this copy pasted code. Polly could also use it, but currently does something different, so I will save the behavior change for a future revision. We get the shared, non-installed CMake modules following the pattern established in D116472. It might be good to have LLD and Flang also use this, but that would be a functional change and so I leave it as future work. Reviewed By: beanz, lebedev.ri Differential Revision: https://reviews.llvm.org/D116521
64 lines
2.4 KiB
CMake
64 lines
2.4 KiB
CMake
include(ExtendPath)
|
|
include(FindPrefixFromConfig)
|
|
|
|
# Generate a list of CMake library targets so that other CMake projects can
|
|
# link against them. LLVM calls its version of this file LLVMExports.cmake, but
|
|
# the usual CMake convention seems to be ${Project}Targets.cmake.
|
|
set(FLANG_INSTALL_PACKAGE_DIR lib${LLVM_LIBDIR_SUFFIX}/cmake/flang)
|
|
set(flang_cmake_builddir "${CMAKE_BINARY_DIR}/${FLANG_INSTALL_PACKAGE_DIR}")
|
|
|
|
# Keep this in sync with llvm/cmake/CMakeLists.txt!
|
|
set(LLVM_INSTALL_PACKAGE_DIR lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm)
|
|
set(llvm_cmake_builddir "${LLVM_BINARY_DIR}/${LLVM_INSTALL_PACKAGE_DIR}")
|
|
|
|
get_property(FLANG_EXPORTS GLOBAL PROPERTY FLANG_EXPORTS)
|
|
export(TARGETS ${FLANG_EXPORTS} FILE ${flang_cmake_builddir}/FlangTargets.cmake)
|
|
|
|
# Generate FlangConfig.cmake for the build tree.
|
|
set(FLANG_CONFIG_CMAKE_DIR "${flang_cmake_builddir}")
|
|
set(FLANG_CONFIG_LLVM_CMAKE_DIR "${llvm_cmake_builddir}")
|
|
set(FLANG_CONFIG_INCLUDE_EXPORTS "include(\"${flang_cmake_builddir}/FlangTargets.cmake\")")
|
|
set(FLANG_CONFIG_INCLUDE_DIRS
|
|
"${FLANG_SOURCE_DIR}/include"
|
|
"${FLANG_BINARY_DIR}/include"
|
|
)
|
|
configure_file(
|
|
${CMAKE_CURRENT_SOURCE_DIR}/FlangConfig.cmake.in
|
|
${flang_cmake_builddir}/FlangConfig.cmake
|
|
@ONLY)
|
|
set(FLANG_CONFIG_CMAKE_DIR)
|
|
set(FLANG_CONFIG_LLVM_CMAKE_DIR)
|
|
|
|
# Generate FlangConfig.cmake for the install tree.
|
|
find_prefix_from_config(FLANG_CONFIG_CODE FLANG_INSTALL_PREFIX "${FLANG_INSTALL_PACKAGE_DIR}")
|
|
|
|
set(FLANG_CONFIG_CMAKE_DIR "\${FLANG_INSTALL_PREFIX}/${FLANG_INSTALL_PACKAGE_DIR}")
|
|
set(FLANG_CONFIG_LLVM_CMAKE_DIR "\${FLANG_INSTALL_PREFIX}/${LLVM_INSTALL_PACKAGE_DIR}")
|
|
get_config_exports_includes(Flang FLANG_CONFIG_INCLUDE_EXPORTS)
|
|
extend_path(FLANG_CONFIG_INCLUDE_DIRS "\${FLANG_INSTALL_PREFIX}" "${CMAKE_INSTALL_INCLUDEDIR}")
|
|
|
|
configure_file(
|
|
${CMAKE_CURRENT_SOURCE_DIR}/FlangConfig.cmake.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/FlangConfig.cmake
|
|
@ONLY)
|
|
|
|
set(FLANG_CONFIG_CODE)
|
|
set(FLANG_CONFIG_CMAKE_DIR)
|
|
set(FLANG_CONFIG_EXPORTS_FILE)
|
|
|
|
if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
|
|
install_distribution_exports(Flang)
|
|
|
|
install(FILES
|
|
${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/FlangConfig.cmake
|
|
DESTINATION ${FLANG_INSTALL_PACKAGE_DIR}
|
|
COMPONENT flang-cmake-exports)
|
|
|
|
if(NOT LLVM_ENABLE_IDE)
|
|
# Add a dummy target so this can be used with LLVM_DISTRIBUTION_COMPONENTS
|
|
add_custom_target(flang-cmake-exports)
|
|
add_llvm_install_targets(install-flang-cmake-exports
|
|
COMPONENT flang-cmake-exports)
|
|
endif()
|
|
endif()
|