mirror of
https://github.com/RPCS3/llvm.git
synced 2025-04-12 11:03:24 +00:00
d39c38d2bc
Switch to MC for instruction printing. This encompasses several changes which are all interconnected: - Use the MC framework for printing almost all instructions. - AsmStrings are now live. - This introduces an indirection between LLVM vregs and WebAssembly registers, and a new pass, WebAssemblyRegNumbering, for computing a basic the mapping. This addresses some basic issues with argument registers and unused registers. - The way ARGUMENT instructions are handled no longer generates redundant get_local+set_local for every argument. This also changes the assembly syntax somewhat; most notably, MC's printing does not use sigils on label names, so those are no longer present, and push/pop now have a sigil to keep them unambiguous. The usage of set_local/get_local/$push/$pop will continue to evolve significantly. This patch is just one step of a larger change. git-svn-id: https://llvm.org/svn/llvm-project/llvm/trunk@252910 91177308-0d34-0410-b5e6-96231b3b80d8
70 lines
2.6 KiB
TableGen
70 lines
2.6 KiB
TableGen
//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
|
|
//
|
|
// The LLVM Compiler Infrastructure
|
|
//
|
|
// This file is distributed under the University of Illinois Open Source
|
|
// License. See LICENSE.TXT for details.
|
|
//
|
|
//===----------------------------------------------------------------------===//
|
|
///
|
|
/// \file
|
|
/// \brief WebAssembly control-flow code-gen constructs.
|
|
///
|
|
//===----------------------------------------------------------------------===//
|
|
|
|
/*
|
|
* TODO(jfb): Add the following.
|
|
*
|
|
* block: a fixed-length sequence of statements
|
|
* if: if statement
|
|
* do_while: do while statement, basically a loop with a conditional branch
|
|
* forever: infinite loop statement (like while (1)), basically an unconditional
|
|
* branch (back to the top of the loop)
|
|
* continue: continue to start of nested loop
|
|
* break: break to end from nested loop or block
|
|
* switch: switch statement with fallthrough
|
|
*/
|
|
|
|
let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
|
|
def BR_IF_ : I<(outs), (ins bb_op:$dst, I32:$a),
|
|
[(brcond I32:$a, bb:$dst)],
|
|
"br_if $dst, $a">;
|
|
let isBarrier = 1 in {
|
|
def BR : I<(outs), (ins bb_op:$dst),
|
|
[(br bb:$dst)],
|
|
"br $dst">;
|
|
} // isBarrier = 1
|
|
} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
|
|
|
|
// TODO: SelectionDAG's lowering insists on using a pointer as the index for
|
|
// jump tables, so in practice we don't ever use SWITCH_I64 in wasm32 mode
|
|
// currently.
|
|
let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
|
|
def SWITCH_I32 : I<(outs), (ins I32:$index, variable_ops),
|
|
[(WebAssemblyswitch I32:$index)],
|
|
"switch $index">;
|
|
def SWITCH_I64 : I<(outs), (ins I64:$index, variable_ops),
|
|
[(WebAssemblyswitch I64:$index)],
|
|
"switch $index">;
|
|
} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
|
|
|
|
// Placemarkers to indicate the start of a block or loop scope.
|
|
def BLOCK : I<(outs), (ins bb_op:$dst), [], "block $dst">;
|
|
def LOOP : I<(outs), (ins bb_op:$dst), [], "loop $dst">;
|
|
|
|
multiclass RETURN<WebAssemblyRegClass vt> {
|
|
def RETURN_#vt : I<(outs), (ins vt:$val), [(WebAssemblyreturn vt:$val)],
|
|
"return $val">;
|
|
}
|
|
|
|
let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
|
|
let isReturn = 1 in {
|
|
defm : RETURN<I32>;
|
|
defm : RETURN<I64>;
|
|
defm : RETURN<F32>;
|
|
defm : RETURN<F64>;
|
|
def RETURN_VOID : I<(outs), (ins), [(WebAssemblyreturn)], "return">;
|
|
} // isReturn = 1
|
|
def UNREACHABLE : I<(outs), (ins), [(trap)], "unreachable">;
|
|
} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
|