mirror of
https://github.com/RPCSX/llvm.git
synced 2024-12-15 16:09:02 +00:00
6050b768b6
Currently the pass updates branch weights in the IR if the function has
any PGO info (entry frequency is set). However we could still have
regions of the CFG that does not have branch weights collected (e.g. a
cold region). In this case we'd use static estimates. Since static
estimates for branches are determined independently, they are
inconsistent. Updating them can "randomly" inflate block frequencies.
I've run into this in a completely cold loop of h264ref from
SPEC. -Rpass-with-hotness showed the loop to be completely cold during
inlining (before JT) but completely hot during vectorization (after JT).
The new testcase demonstrate the problem. We check array elements
against 1, 2 and 3 in a loop. The check against 3 is the loop-exiting
check. The block names should be self-explanatory.
In this example, jump threading incorrectly updates the weight of the
loop-exiting branch to 0, drastically inflating the frequency of the
loop (in the range of billions).
There is no run-time profile info for edges inside the loop, so branch
probabilities are estimated. These are the resulting branch and block
frequencies for the loop body:
check_1 (16)
(8) / |
eq_1 | (8)
\ |
check_2 (16)
(8) / |
eq_2 | (8)
\ |
check_3 (16)
(1) / |
(loop exit) | (15)
|
(back edge)
First we thread eq_1 -> check_2 to check_3. Frequencies are updated to
remove the frequency of eq_1 from check_2 and then from the false edge
leaving check_2. Changed frequencies are highlighted with * *:
check_1 (16)
(8) / |
eq_1~ | (8)
/ |
/ check_2 (*8*)
/ (8) / |
\ eq_2 | (*0*)
\ \ |
` --- check_3 (16)
(1) / |
(loop exit) | (15)
|
(back edge)
Next we thread eq_1 -> check_3 and eq_2 -> check_3 to check_1 as new
back edges. Frequencies are updated to remove the frequency of eq_1 and
eq_3 from check_3 and then the false edge leaving check_3 (changed
frequencies are highlighted with * *):
check_1 (16)
(8) / |
eq_1~ | (8)
/ |
/ check_2 (*8*)
/ (8) / |
/-- eq_2~ | (*0*)
(back edge) |
check_3 (*0*)
(*0*) / |
(loop exit) | (*0*)
|
(back edge)
As a result, the loop exit edge ends up with 0 frequency which in turn makes
the loop header to have maximum frequency.
There are a few potential problems here:
1. The profile data seems odd. There is a single profile sample of the
loop being entered. On the other hand, there are no weights inside the
loop.
2. Based on static estimation we shouldn't set edges to "extreme"
values, i.e. extremely likely or unlikely.
3. We shouldn't create profile metadata that is calculated from static
estimation. I am not sure what policy is but it seems to make sense to
treat profile metadata as something that is known to originate from
profiling. Estimated probabilities should only be reflected in BPI/BFI.
Any one of these would probably fix the immediate problem. I went for 3
because I think it's a good policy to have and added a FIXME about 2.
Differential Revision: https://reviews.llvm.org/D24118
git-svn-id: https://llvm.org/svn/llvm-project/llvm/trunk@280713 91177308-0d34-0410-b5e6-96231b3b80d8
120 lines
3.4 KiB
LLVM
120 lines
3.4 KiB
LLVM
; RUN: opt -S -jump-threading < %s | FileCheck %s
|
|
|
|
; Check that based solely on static profile estimation we don't update the
|
|
; branch-weight metadata. Even if the function has an entry frequency, a
|
|
; completely cold part of the CFG may be statically estimated.
|
|
|
|
; For example in the loop below, jump threading would update the weight of the
|
|
; loop-exiting branch to 0, drastically inflating the frequency of the loop
|
|
; (in the range of billions).
|
|
;
|
|
; This is the CFG of the loop. There is no run-time profile info for edges
|
|
; inside the loop, so branch and block frequencies are estimated as shown:
|
|
;
|
|
; check_1 (16)
|
|
; (8) / |
|
|
; eq_1 | (8)
|
|
; \ |
|
|
; check_2 (16)
|
|
; (8) / |
|
|
; eq_2 | (8)
|
|
; \ |
|
|
; check_3 (16)
|
|
; (1) / |
|
|
; (loop exit) | (15)
|
|
; |
|
|
; (back edge)
|
|
;
|
|
; First we thread eq_1->check_2 to check_3. Frequencies are updated to remove
|
|
; the frequency of eq_1 from check_2 and then the false edge leaving check_2
|
|
; (changed frequencies are highlighted with * *):
|
|
;
|
|
; check_1 (16)
|
|
; (8) / |
|
|
; eq_1~ | (8)
|
|
; / |
|
|
; / check_2 (*8*)
|
|
; / (8) / |
|
|
; \ eq_2 | (*0*)
|
|
; \ \ |
|
|
; ` --- check_3 (16)
|
|
; (1) / |
|
|
; (loop exit) | (15)
|
|
; |
|
|
; (back edge)
|
|
;
|
|
; Next we thread eq_1->check_3 and eq_2->check_3 to check_1 as new back edges.
|
|
; Frequencies are updated to remove the frequency of eq_1 and eq_3 from
|
|
; check_3 and then the false edge leaving check_3 (changed frequencies are
|
|
; highlighted with * *):
|
|
;
|
|
; check_1 (16)
|
|
; (8) / |
|
|
; eq_1~ | (8)
|
|
; / |
|
|
; / check_2 (*8*)
|
|
; / (8) / |
|
|
; /-- eq_2~ | (*0*)
|
|
; (back edge) |
|
|
; check_3 (*0*)
|
|
; (*0*) / |
|
|
; (loop exit) | (*0*)
|
|
; |
|
|
; (back edge)
|
|
;
|
|
; As a result, the loop exit edge ends up with 0 frequency which in turn makes
|
|
; the loop header to have maximum frequency.
|
|
|
|
declare void @bar()
|
|
|
|
define void @foo(i32 *%p, i32 %n) !prof !0 {
|
|
entry:
|
|
%enter_loop = icmp eq i32 %n, 0
|
|
br i1 %enter_loop, label %exit, label %check_1, !prof !1
|
|
; CHECK: br i1 %enter_loop, label %exit, label %check_1, !prof !1
|
|
|
|
check_1:
|
|
%v = load i32, i32* %p
|
|
%cond1 = icmp eq i32 %v, 1
|
|
br i1 %cond1, label %eq_1, label %check_2
|
|
; No metadata:
|
|
; CHECK: br i1 %cond1, label %check_2.thread, label %check_2{{$}}
|
|
|
|
eq_1:
|
|
call void @bar()
|
|
br label %check_2
|
|
; Verify the new backedge:
|
|
; CHECK: check_2.thread:
|
|
; CHECK-NEXT: call void @bar()
|
|
; CHECK-NEXT: br label %check_1
|
|
|
|
check_2:
|
|
%cond2 = icmp eq i32 %v, 2
|
|
br i1 %cond2, label %eq_2, label %check_3
|
|
; No metadata:
|
|
; CHECK: br i1 %cond2, label %eq_2, label %check_3{{$}}
|
|
|
|
eq_2:
|
|
call void @bar()
|
|
br label %check_3
|
|
; Verify the new backedge:
|
|
; CHECK: eq_2:
|
|
; CHECK-NEXT: call void @bar()
|
|
; CHECK-NEXT: br label %check_1
|
|
|
|
check_3:
|
|
%condE = icmp eq i32 %v, 3
|
|
br i1 %condE, label %exit, label %check_1
|
|
; No metadata:
|
|
; CHECK: br i1 %condE, label %exit, label %check_1{{$}}
|
|
|
|
exit:
|
|
ret void
|
|
}
|
|
|
|
!0 = !{!"function_entry_count", i64 120}
|
|
; CHECK-NOT: branch_weights
|
|
!1 = !{!"branch_weights", i32 119, i32 1}
|
|
; CHECK: !1 = !{!"branch_weights", i32 119, i32 1}
|
|
; CHECK-NOT: branch_weights
|