mirror of
https://github.com/darlinghq/darling-gdb.git
synced 2024-12-11 06:04:12 +00:00
320d4f291f
* configure.in: Call AC_CONFIG_HEADER with config.h:config.in. Check for config.h:config.in when creating stamp-h. * configure: Rebuild. * Makefile.in (stamp-h): Depend upon config.in rather than config.h.in. Set CONFIG_HEADERS to config.h:config.in when calling config.status.
187 lines
4.6 KiB
Plaintext
187 lines
4.6 KiB
Plaintext
dnl Process this file with autoconf to produce a configure script.
|
|
dnl
|
|
AC_PREREQ(2.0)
|
|
AC_INIT(ar.c)
|
|
|
|
AC_ARG_ENABLE(targets,
|
|
[ --enable-targets alternative target configurations],
|
|
[case "${enableval}" in
|
|
yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
|
|
;;
|
|
no) enable_targets= ;;
|
|
*) enable_targets=$enableval ;;
|
|
esac])dnl
|
|
|
|
AC_CONFIG_HEADER(config.h:config.in)
|
|
|
|
AC_CONFIG_AUX_DIR(`cd $srcdir/..; pwd`)
|
|
AC_CANONICAL_SYSTEM
|
|
if test -z "$target" ; then
|
|
AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
|
|
fi
|
|
if test -z "$host" ; then
|
|
AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
|
|
fi
|
|
AC_ARG_PROGRAM
|
|
|
|
# host-specific stuff:
|
|
|
|
HDEFINES=
|
|
LDFLAGS=
|
|
|
|
. ${srcdir}/../bfd/configure.host
|
|
|
|
AC_PROG_CC
|
|
AC_SUBST(CFLAGS)
|
|
AC_SUBST(HDEFINES)
|
|
AC_SUBST(LDFLAGS)
|
|
AR=${AR-ar}
|
|
AC_SUBST(AR)
|
|
AC_PROG_RANLIB
|
|
AC_PROG_INSTALL
|
|
|
|
BFD_CC_FOR_BUILD
|
|
|
|
AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h)
|
|
AC_CHECK_FUNCS(sbrk utimes)
|
|
|
|
AC_MSG_CHECKING(for time_t in time.h)
|
|
AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
|
|
[AC_TRY_COMPILE([#include <time.h>], [time_t i;],
|
|
bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
|
|
AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
|
|
if test $bu_cv_decl_time_t_time_h = yes; then
|
|
AC_DEFINE([HAVE_TIME_T_IN_TIME_H])
|
|
fi
|
|
|
|
AC_MSG_CHECKING(for time_t in sys/types.h)
|
|
AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
|
|
[AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
|
|
bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
|
|
AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
|
|
if test $bu_cv_decl_time_t_types_h = yes; then
|
|
AC_DEFINE([HAVE_TIME_T_IN_TYPES_H])
|
|
fi
|
|
|
|
# Under Next 3.2 <utime.h> apparently does not define struct utimbuf
|
|
# by default.
|
|
AC_MSG_CHECKING([for utime.h])
|
|
AC_CACHE_VAL(bu_cv_header_utime_h,
|
|
[AC_TRY_COMPILE([#include <sys/types.h>
|
|
#ifdef HAVE_TIME_H
|
|
#include <time.h>
|
|
#endif
|
|
#include <utime.h>],
|
|
[struct utimbuf s;],
|
|
bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
|
|
AC_MSG_RESULT($bu_cv_header_utime_h)
|
|
if test $bu_cv_header_utime_h = yes; then
|
|
AC_DEFINE(HAVE_GOOD_UTIME_H)
|
|
fi
|
|
|
|
AC_MSG_CHECKING([whether fprintf must be declared])
|
|
AC_CACHE_VAL(bu_cv_decl_needed_fprintf,
|
|
[AC_TRY_COMPILE([#include <stdio.h>],
|
|
[int (*pfn) = (int (*)) fprintf],
|
|
bu_cv_decl_needed_fprintf=no, bu_cv_decl_needed_fprintf=yes)])
|
|
AC_MSG_RESULT($bu_cv_decl_needed_fprintf)
|
|
if test $bu_cv_decl_needed_fprintf = yes; then
|
|
AC_DEFINE(NEED_DECLARATION_FPRINTF)
|
|
fi
|
|
|
|
BFD_BINARY_FOPEN
|
|
|
|
# target-specific stuff:
|
|
|
|
# Canonicalize the secondary target names.
|
|
target_makefile_fragment=/dev/null
|
|
if test -n "$enable_targets"; then
|
|
for targ in `echo $enable_targets | sed 's/,/ /g'`
|
|
do
|
|
result=`$ac_config_sub $targ 2>/dev/null`
|
|
if test -n "$result"; then
|
|
canon_targets="$canon_targets $result"
|
|
else
|
|
# Allow targets that config.sub doesn't recognize, like "all".
|
|
canon_targets="$canon_targets $targ"
|
|
fi
|
|
done
|
|
else
|
|
# If our target is rs6000 _and nothing else_ then we build only nm!
|
|
case $target in
|
|
rs6000-*-lynx*) target_makefile_fragment=${srcdir}/config/rslynx ;;
|
|
esac
|
|
fi
|
|
AC_SUBST_FILE(target_makefile_fragment)
|
|
|
|
all_targets=false
|
|
BUILD_NLMCONV=
|
|
NLMCONV_DEFS=
|
|
BUILD_SRCONV=
|
|
BUILD_DLLTOOL=
|
|
DLLTOOL_DEFS=
|
|
|
|
for targ in $target $canon_targets
|
|
do
|
|
if test "x$targ" = "xall"; then
|
|
all_targets=true
|
|
BUILD_NLMCONV='$(NLMCONV_PROG)'
|
|
BUILD_SRCONV='$(SRCONV_PROG)'
|
|
NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
|
|
else
|
|
case $targ in
|
|
changequote(,)dnl
|
|
i[345]86*-*-netware*)
|
|
changequote([,])dnl
|
|
BUILD_NLMCONV='$(NLMCONV_PROG)'
|
|
NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
|
|
;;
|
|
alpha*-*-netware*)
|
|
BUILD_NLMCONV='$(NLMCONV_PROG)'
|
|
NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
|
|
;;
|
|
powerpc*-*-netware*)
|
|
BUILD_NLMCONV='$(NLMCONV_PROG)'
|
|
NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
|
|
;;
|
|
sparc*-*-netware*)
|
|
BUILD_NLMCONV='$(NLMCONV_PROG)'
|
|
NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
|
|
;;
|
|
esac
|
|
case $targ in
|
|
*-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
|
|
esac
|
|
case $targ in
|
|
arm-*pe*)
|
|
BUILD_DLLTOOL='$(DLLTOOL_PROG)'
|
|
DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
|
|
;;
|
|
changequote(,)dnl
|
|
i[3-6]86-*pe* | i[3-6]86-*-win32)
|
|
changequote([,])dnl
|
|
BUILD_DLLTOOL='$(DLLTOOL_PROG)'
|
|
DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
|
|
;;
|
|
esac
|
|
fi
|
|
done
|
|
|
|
AC_SUBST(NLMCONV_DEFS)
|
|
AC_SUBST(BUILD_NLMCONV)
|
|
AC_SUBST(BUILD_SRCONV)
|
|
AC_SUBST(BUILD_DLLTOOL)
|
|
AC_SUBST(DLLTOOL_DEFS)
|
|
|
|
targ=$target
|
|
. $srcdir/../bfd/config.bfd
|
|
if test "x$targ_underscore" = "xyes"; then
|
|
UNDERSCORE=1
|
|
else
|
|
UNDERSCORE=0
|
|
fi
|
|
AC_SUBST(UNDERSCORE)
|
|
|
|
AC_OUTPUT(Makefile,
|
|
[case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])
|