mirror of
https://github.com/darlinghq/darling-gdb.git
synced 2024-11-29 15:00:34 +00:00
11f91b2bbc
and "post_add_symbol_hook". These hooks are called before we begin reading
symbols, and after we finish.
(generic_load): Use new symbol reading hooks and get rid of compiler warning.
* gdbtk.c (gdbtk_init): Add hooks for pre- and post-symbol reading.
(gdbtk_pre_add_symbol): New function: the pre-add-symbol hook.
(gdbtk_post_add_symbol): New function: the post-add-symbol hook.
(find_file_in_dir): New function. Moved the guts of gdb_find_file_command
into here to allow its use by others.
(gdb_loc): Use find_file_in_dir to return the real path to the file
(or "N/A" if we can't find it).
* configure.in (TIX_LIB_EXT): Define new variable for those special cases
when TCL_SHLIB_SUFFIX is not enough to specify the dependency.
* configure: Regenerate.
606 lines
16 KiB
Plaintext
606 lines
16 KiB
Plaintext
dnl Autoconf configure script for GDB, the GNU debugger.
|
|
dnl Copyright 1995, 1996 Free Software Foundation, Inc.
|
|
dnl
|
|
dnl This file is part of GDB.
|
|
dnl
|
|
dnl This program is free software; you can redistribute it and/or modify
|
|
dnl it under the terms of the GNU General Public License as published by
|
|
dnl the Free Software Foundation; either version 2 of the License, or
|
|
dnl (at your option) any later version.
|
|
dnl
|
|
dnl This program is distributed in the hope that it will be useful,
|
|
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
dnl GNU General Public License for more details.
|
|
dnl
|
|
dnl You should have received a copy of the GNU General Public License
|
|
dnl along with this program; if not, write to the Free Software
|
|
dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
|
|
|
|
dnl Process this file with autoconf to produce a configure script.
|
|
|
|
AC_PREREQ(2.5)dnl
|
|
AC_INIT(main.c)
|
|
AC_CONFIG_HEADER(config.h:config.in)
|
|
|
|
AC_PROG_CC
|
|
AC_AIX
|
|
AC_MINIX
|
|
AC_ISC_POSIX
|
|
|
|
DLLTOOL=${DLLTOOL-dlltool}
|
|
AC_SUBST(DLLTOOL)
|
|
|
|
AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
|
|
AC_CANONICAL_SYSTEM
|
|
|
|
dnl List of object files added by configure.
|
|
|
|
CONFIG_OBS=
|
|
CONFIG_DEPS=
|
|
|
|
configdirs="doc testsuite"
|
|
|
|
dnl
|
|
changequote(,)dnl
|
|
|
|
. ${srcdir}/configure.host
|
|
|
|
. ${srcdir}/configure.tgt
|
|
|
|
dnl
|
|
changequote([,])dnl
|
|
|
|
AC_PROG_INSTALL
|
|
AC_CHECK_TOOL(AR, ar)
|
|
AC_CHECK_TOOL(RANLIB, ranlib, :)
|
|
AC_PROG_YACC
|
|
AC_PROG_AWK
|
|
|
|
AC_ARG_PROGRAM
|
|
|
|
AC_TYPE_SIGNAL
|
|
|
|
AC_HEADER_STDC
|
|
AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
|
|
AC_HEADER_STAT
|
|
|
|
AC_C_CONST
|
|
|
|
AC_CHECK_FUNCS(setpgid sbrk select poll sigaction)
|
|
|
|
# If we are configured native on Linux, work around problems with sys/procfs.h
|
|
if test "${target}" = "${host}"; then
|
|
case "${host}" in
|
|
i[[3456]]86-*-linux*)
|
|
AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
|
|
AC_DEFINE(sys_quotactl)
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
AC_MSG_CHECKING([for gregset_t type])
|
|
AC_CACHE_VAL(gdb_cv_have_gregset_t,
|
|
[AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
|
|
gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
|
|
AC_MSG_RESULT($gdb_cv_have_gregset_t)
|
|
if test $gdb_cv_have_gregset_t = yes; then
|
|
AC_DEFINE(HAVE_GREGSET_T)
|
|
fi
|
|
|
|
AC_MSG_CHECKING([for fpregset_t type])
|
|
AC_CACHE_VAL(gdb_cv_have_fpregset_t,
|
|
[AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
|
|
gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
|
|
AC_MSG_RESULT($gdb_cv_have_fpregset_t)
|
|
if test $gdb_cv_have_fpregset_t = yes; then
|
|
AC_DEFINE(HAVE_FPREGSET_T)
|
|
fi
|
|
|
|
dnl See if host has libm. This is usually needed by simulators.
|
|
AC_CHECK_LIB(m, main)
|
|
|
|
dnl See if compiler supports "long long" type.
|
|
|
|
AC_MSG_CHECKING(for long long support in compiler)
|
|
AC_CACHE_VAL(gdb_cv_c_long_long,
|
|
[AC_TRY_COMPILE(, [
|
|
extern long long foo;
|
|
switch (foo & 2) { case 0: return 1; }
|
|
],
|
|
gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
|
|
AC_MSG_RESULT($gdb_cv_c_long_long)
|
|
if test $gdb_cv_c_long_long = yes; then
|
|
AC_DEFINE(CC_HAS_LONG_LONG)
|
|
fi
|
|
|
|
dnl See if the compiler and runtime support printing long long
|
|
|
|
AC_MSG_CHECKING(for long long support in printf)
|
|
AC_CACHE_VAL(gdb_cv_printf_has_long_long,
|
|
[AC_TRY_RUN([
|
|
int main () {
|
|
char buf[32];
|
|
long long l = 0;
|
|
l = (l << 16) + 0x0123;
|
|
l = (l << 16) + 0x4567;
|
|
l = (l << 16) + 0x89ab;
|
|
l = (l << 16) + 0xcdef;
|
|
sprintf (buf, "0x%016llx", l);
|
|
return (strcmp ("0x0123456789abcdef", buf));
|
|
}],
|
|
gdb_cv_printf_has_long_long=yes,
|
|
gdb_cv_printf_has_long_long=no,
|
|
gdb_cv_printf_has_long_long=no)])
|
|
if test $gdb_cv_printf_has_long_long = yes; then
|
|
AC_DEFINE(PRINTF_HAS_LONG_LONG)
|
|
fi
|
|
AC_MSG_RESULT($gdb_cv_printf_has_long_long)
|
|
|
|
dnl See if compiler supports "long double" type. Can't use AC_C_LONG_DOUBLE
|
|
dnl because autoconf complains about cross-compilation issues. However, this
|
|
dnl code uses the same variables as the macro for compatibility.
|
|
|
|
AC_MSG_CHECKING(for long double support in compiler)
|
|
AC_CACHE_VAL(ac_cv_c_long_double,
|
|
[AC_TRY_COMPILE(, [long double foo;],
|
|
ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
|
|
AC_MSG_RESULT($ac_cv_c_long_double)
|
|
if test $ac_cv_c_long_double = yes; then
|
|
AC_DEFINE(HAVE_LONG_DOUBLE)
|
|
fi
|
|
|
|
dnl See if the compiler and runtime support printing long doubles
|
|
|
|
AC_MSG_CHECKING(for long double support in printf)
|
|
AC_CACHE_VAL(gdb_cv_printf_has_long_double,
|
|
[AC_TRY_RUN([
|
|
int main () {
|
|
char buf[16];
|
|
long double f = 3.141592653;
|
|
sprintf (buf, "%Lg", f);
|
|
return (strncmp ("3.14159", buf, 7));
|
|
}],
|
|
gdb_cv_printf_has_long_double=yes,
|
|
gdb_cv_printf_has_long_double=no,
|
|
gdb_cv_printf_has_long_double=no)])
|
|
if test $gdb_cv_printf_has_long_double = yes; then
|
|
AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
|
|
fi
|
|
AC_MSG_RESULT($gdb_cv_printf_has_long_double)
|
|
|
|
dnl See if the compiler and runtime support scanning long doubles
|
|
|
|
AC_MSG_CHECKING(for long double support in scanf)
|
|
AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
|
|
[AC_TRY_RUN([
|
|
int main () {
|
|
char *buf = "3.141592653";
|
|
long double f = 0;
|
|
sscanf (buf, "%Lg", &f);
|
|
return !(f > 3.14159 && f < 3.14160);
|
|
}],
|
|
gdb_cv_scanf_has_long_double=yes,
|
|
gdb_cv_scanf_has_long_double=no,
|
|
gdb_cv_scanf_has_long_double=no)])
|
|
if test $gdb_cv_scanf_has_long_double = yes; then
|
|
AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
|
|
fi
|
|
AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
|
|
|
|
AC_FUNC_MMAP
|
|
|
|
BFD_NEED_DECLARATION(malloc)
|
|
BFD_NEED_DECLARATION(realloc)
|
|
BFD_NEED_DECLARATION(free)
|
|
|
|
dnl See if thread_db library is around for Solaris thread debugging. Note that
|
|
dnl we must explicitly test for version 1 of the library because version 0
|
|
dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
|
|
|
|
dnl Note that we only want this if we are both native (host == target), and
|
|
dnl not doing a canadian cross build (build == host).
|
|
|
|
if test ${build} = ${host} -a ${host} = ${target} ; then
|
|
case ${host_os} in
|
|
hpux*)
|
|
AC_MSG_CHECKING(for HPUX/OSF thread support)
|
|
if test -f /usr/include/dce/cma_config.h ; then
|
|
if test "$GCC" = "yes" ; then
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
|
|
CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
|
|
else
|
|
AC_MSG_RESULT(no (suppressed because you are not using GCC))
|
|
fi
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
;;
|
|
solaris*)
|
|
AC_MSG_CHECKING(for Solaris thread debugging library)
|
|
if test -f /usr/lib/libthread_db.so.1 ; then
|
|
AC_MSG_RESULT(yes)
|
|
AC_DEFINE(HAVE_THREAD_DB_LIB)
|
|
CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
|
|
AC_CHECK_LIB(dl, dlopen)
|
|
if test "$GCC" = "yes" ; then
|
|
CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
|
|
fi
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
;;
|
|
esac
|
|
AC_SUBST(CONFIG_LDFLAGS)
|
|
fi
|
|
|
|
dnl Handle optional features that can be enabled.
|
|
ENABLE_CFLAGS=
|
|
|
|
AC_ARG_ENABLE(netrom,
|
|
[ --enable-netrom ],
|
|
[case "${enableval}" in
|
|
yes) enable_netrom=yes ;;
|
|
no) enable_netrom=no ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
|
|
esac])
|
|
|
|
if test "${enable_netrom}" = "yes"; then
|
|
CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
|
|
fi
|
|
|
|
MMALLOC_CFLAGS=
|
|
MMALLOC=
|
|
AC_SUBST(MMALLOC_CFLAGS)
|
|
AC_SUBST(MMALLOC)
|
|
|
|
AC_ARG_WITH(mmalloc,
|
|
[ --with-mmalloc use memory mapped malloc package],
|
|
[case "${withval}" in
|
|
yes) want_mmalloc=true ;;
|
|
no) want_mmalloc=false;;
|
|
*) AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
|
|
esac],[want_mmalloc=false])dnl
|
|
|
|
if test x$want_mmalloc = xtrue; then
|
|
AC_DEFINE(USE_MMALLOC)
|
|
AC_DEFINE(FORCE_MMCHECK)
|
|
MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
|
|
MMALLOC='../mmalloc/libmmalloc.a'
|
|
fi
|
|
|
|
# start-sanitize-gdbtk
|
|
ENABLE_IDE=
|
|
AC_ARG_ENABLE(ide, [ --enable-ide Enable IDE support])
|
|
if test "$enable_ide" = yes; then
|
|
enable_ide=yes
|
|
ENABLE_IDE=1
|
|
else
|
|
enable_ide=no
|
|
fi
|
|
AC_SUBST(ENABLE_IDE)
|
|
|
|
ENABLE_GDBTK=
|
|
|
|
AC_ARG_ENABLE(gdbtk,
|
|
[ --enable-gdbtk ],
|
|
[case "${enableval}" in
|
|
yes)
|
|
case "$host" in
|
|
*go32*)
|
|
AC_MSG_WARN([GDB does not support GDBtk on host ${host}. GDBtk will be disabled.])
|
|
enable_gdbtk=no ;;
|
|
*windows*)
|
|
AC_MSG_WARN([GDB does not support GDBtk on host ${host}. GDBtk will be disabled.])
|
|
enable_gdbtk=no ;;
|
|
*)
|
|
enable_gdbtk=yes ;;
|
|
esac ;;
|
|
no)
|
|
enable_gdbtk=no ;;
|
|
*)
|
|
AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
|
|
esac],
|
|
[
|
|
# Default is on for everything but go32 and cygwin32
|
|
case "$host" in
|
|
*go32* | *windows*)
|
|
;;
|
|
*)
|
|
enable_gdbtk=yes ;;
|
|
esac
|
|
])
|
|
|
|
# In the cygwin32 environment, we need some additional flags.
|
|
AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
|
|
[AC_EGREP_CPP(lose, [
|
|
#ifdef __CYGWIN32__
|
|
lose
|
|
#endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
|
|
|
|
WIN32LIBS=
|
|
WIN32LDAPP=
|
|
AC_SUBST(WIN32LIBS)
|
|
AC_SUBST(WIN32LDAPP)
|
|
|
|
if test x$gdb_cv_os_cygwin32 = xyes; then
|
|
if test x$enable_ide = xyes; then
|
|
WIN32LIBS="-ladvapi32"
|
|
fi
|
|
fi
|
|
|
|
configdir="unix"
|
|
|
|
if test "${enable_gdbtk}" = "yes"; then
|
|
|
|
CY_AC_PATH_TCLCONFIG
|
|
if test -z "${no_tcl}"; then
|
|
CY_AC_LOAD_TCLCONFIG
|
|
CY_AC_PATH_TKCONFIG
|
|
|
|
# If $no_tk is nonempty, then we can't do Tk, and there is no
|
|
# point to doing Tcl.
|
|
if test -z "${no_tk}"; then
|
|
CY_AC_LOAD_TKCONFIG
|
|
CY_AC_PATH_TCLH
|
|
CY_AC_PATH_TKH
|
|
CY_AC_PATH_ITCLH
|
|
CY_AC_PATH_TIX
|
|
|
|
# now look for tix library stuff
|
|
TIXVERSION=4.1.8.0
|
|
. ${ac_cv_c_tclconfig}/tclConfig.sh
|
|
case "${host}" in
|
|
*-*-cygwin32*)
|
|
tixdir=../tix/win/tcl8.0
|
|
;;
|
|
*)
|
|
tixdir=../tix/unix/tk8.0
|
|
;;
|
|
esac
|
|
if test "${TCL_SHARED_BUILD}" = "1"; then
|
|
TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
|
|
|
|
# Can't win them all: SunOS 4 (others?) appends a version
|
|
# number after the ".so"
|
|
case "${host}" in
|
|
*-*-sunos4*)
|
|
TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
|
|
esac
|
|
|
|
else
|
|
TIX_LIB_EXT=".a"
|
|
fi
|
|
|
|
if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
|
|
TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
|
|
TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
|
|
else
|
|
TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
|
|
TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
|
|
fi
|
|
|
|
ENABLE_GDBTK=1
|
|
|
|
# Include some libraries that Tcl and Tk want.
|
|
if test "${enable_ide}" = "yes"; then
|
|
TCL_LIBS='$(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
|
|
CONFIG_DEPS='$(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
|
|
else
|
|
TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
|
|
CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
|
|
fi
|
|
# Yes, the ordering seems wrong here. But it isn't.
|
|
# TK_LIBS is the list of libraries that need to be linked
|
|
# after Tcl/Tk.
|
|
LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
|
|
CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
|
|
|
|
if test x$gdb_cv_os_cygwin32 = xyes; then
|
|
WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
|
|
WIN32LDAPP="-Wl,--subsystem,windows"
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
|
|
AC_SUBST(ENABLE_GDBTK)
|
|
AC_SUBST(X_CFLAGS)
|
|
AC_SUBST(X_LDFLAGS)
|
|
AC_SUBST(X_LIBS)
|
|
AC_SUBST(TIXLIB)
|
|
AC_SUBST(TIX_DEPS)
|
|
# end-sanitize-gdbtk
|
|
|
|
AC_SUBST(ENABLE_CFLAGS)
|
|
|
|
AC_SUBST(CONFIG_OBS)
|
|
AC_SUBST(CONFIG_DEPS)
|
|
|
|
# Begin stuff to support --enable-shared
|
|
AC_ARG_ENABLE(shared,
|
|
[ --enable-shared use shared libraries],
|
|
[case "${enableval}" in
|
|
yes) shared=true ;;
|
|
no) shared=false ;;
|
|
*) shared=true ;;
|
|
esac])dnl
|
|
|
|
HLDFLAGS=
|
|
HLDENV=
|
|
# If we have shared libraries, try to set rpath reasonably.
|
|
if test "${shared}" = "true"; then
|
|
case "${host}" in
|
|
*-*-hpux*)
|
|
HLDFLAGS='-Wl,+s,+b,$(libdir)'
|
|
;;
|
|
*-*-irix5* | *-*-irix6*)
|
|
HLDFLAGS='-Wl,-rpath,$(libdir)'
|
|
;;
|
|
*-*-linux*aout*)
|
|
;;
|
|
*-*-linux* | *-pc-linux-gnu)
|
|
HLDFLAGS='-Wl,-rpath,$(libdir)'
|
|
;;
|
|
*-*-solaris*)
|
|
HLDFLAGS='-R $(libdir)'
|
|
;;
|
|
*-*-sysv4*)
|
|
HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
# On SunOS, if the linker supports the -rpath option, use it to
|
|
# prevent ../bfd and ../opcodes from being included in the run time
|
|
# search path.
|
|
case "${host}" in
|
|
*-*-sunos*)
|
|
echo 'main () { }' > conftest.c
|
|
${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
|
|
if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
|
|
:
|
|
elif grep 'No such file' conftest.t >/dev/null 2>&1; then
|
|
:
|
|
elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
|
|
:
|
|
elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
|
|
:
|
|
elif test "${shared}" = "true"; then
|
|
HLDFLAGS='-Wl,-rpath=$(libdir)'
|
|
else
|
|
HLDFLAGS='-Wl,-rpath='
|
|
fi
|
|
rm -f conftest.t conftest.c conftest
|
|
;;
|
|
esac
|
|
AC_SUBST(HLDFLAGS)
|
|
AC_SUBST(HLDENV)
|
|
# End stuff to support --enable-shared
|
|
|
|
# target_subdir is used by the testsuite to find the target libraries.
|
|
target_subdir=
|
|
if test "${host}" != "${target}"; then
|
|
target_subdir="${target_alias}/"
|
|
fi
|
|
AC_SUBST(target_subdir)
|
|
|
|
frags=
|
|
host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
|
|
if test ! -f ${host_makefile_frag}; then
|
|
AC_MSG_ERROR("*** Gdb does not support host ${host}")
|
|
fi
|
|
frags="$frags $host_makefile_frag"
|
|
|
|
target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
|
|
if test ! -f ${target_makefile_frag}; then
|
|
AC_MSG_ERROR("*** Gdb does not support target ${target}")
|
|
fi
|
|
frags="$frags $target_makefile_frag"
|
|
|
|
AC_SUBST_FILE(host_makefile_frag)
|
|
AC_SUBST_FILE(target_makefile_frag)
|
|
AC_SUBST(frags)
|
|
|
|
changequote(,)dnl
|
|
hostfile=`sed -n '
|
|
s/XM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
|
|
' ${host_makefile_frag}`
|
|
|
|
targetfile=`sed -n '
|
|
s/TM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
|
|
' ${target_makefile_frag}`
|
|
|
|
# these really aren't orthogonal true/false values of the same condition,
|
|
# but shells are slow enough that I like to reuse the test conditions
|
|
# whenever possible
|
|
if test "${target}" = "${host}"; then
|
|
nativefile=`sed -n '
|
|
s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
|
|
' ${host_makefile_frag}`
|
|
# else
|
|
# GDBserver is only useful in a "native" enviroment
|
|
# configdirs=`echo $configdirs | sed 's/gdbserver//'`
|
|
fi
|
|
changequote([,])
|
|
|
|
# If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
|
|
# (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
|
|
# corresponding links. But we have to remove the xm.h files and tm.h
|
|
# files anyway, e.g. when switching from "configure host" to
|
|
# "configure none".
|
|
|
|
files=
|
|
links=
|
|
rm -f xm.h
|
|
if test "${hostfile}" != ""; then
|
|
files="${files} config/${gdb_host_cpu}/${hostfile}"
|
|
links="${links} xm.h"
|
|
fi
|
|
rm -f tm.h
|
|
if test "${targetfile}" != ""; then
|
|
files="${files} config/${gdb_target_cpu}/${targetfile}"
|
|
links="${links} tm.h"
|
|
fi
|
|
rm -f nm.h
|
|
if test "${nativefile}" != ""; then
|
|
files="${files} config/${gdb_host_cpu}/${nativefile}"
|
|
links="${links} nm.h"
|
|
else
|
|
# A cross-only configuration.
|
|
files="${files} config/nm-empty.h"
|
|
links="${links} nm.h"
|
|
fi
|
|
# start-sanitize-gdbtk
|
|
AC_PROG_LN_S
|
|
# Make it possible to use the GUI without doing a full install
|
|
if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
|
|
if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
|
|
echo linking $srcdir/gdbtcl to gdbtcl
|
|
$LN_S $srcdir/gdbtcl gdbtcl
|
|
else
|
|
echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl. You will need to do a
|
|
echo " " make install before you are able to run the GUI.
|
|
fi
|
|
fi
|
|
# end-sanitize-gdbtk
|
|
|
|
AC_LINK_FILES($files, $links)
|
|
|
|
dnl Check for exe extension set on certain hosts (e.g. Win32)
|
|
AM_EXEEXT
|
|
|
|
AC_CONFIG_SUBDIRS($configdirs)
|
|
AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
|
|
[
|
|
dnl Autoconf doesn't provide a mechanism for modifying definitions
|
|
dnl provided by makefile fragments.
|
|
dnl
|
|
if test "${nativefile}" = ""; then
|
|
sed -e '/^NATDEPFILES[[ ]]*=[[ ]]*/s//# NATDEPFILES=/' \
|
|
< Makefile > Makefile.tem
|
|
mv -f Makefile.tem Makefile
|
|
fi
|
|
|
|
changequote(,)dnl
|
|
sed -e '/^TM_FILE[ ]*=/s,^TM_FILE[ ]*=[ ]*,&config/'"${gdb_target_cpu}"'/,
|
|
/^XM_FILE[ ]*=/s,^XM_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,
|
|
/^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
|
|
mv -f Makefile.tmp Makefile
|
|
changequote([,])dnl
|
|
|
|
case x$CONFIG_HEADERS in
|
|
xconfig.h:config.in)
|
|
echo > stamp-h ;;
|
|
esac
|
|
],
|
|
[
|
|
gdb_host_cpu=$gdb_host_cpu
|
|
gdb_target_cpu=$gdb_target_cpu
|
|
nativefile=$nativefile
|
|
])
|
|
|
|
exit 0
|
|
|