mirror of
https://github.com/darlinghq/darling-gdb.git
synced 2024-11-30 23:40:24 +00:00
1b05fbbd2c
PR target/37137 * Makefile.def (flags_to_pass): Remove redundant and incomplete STAGE1_CFLAGS, STAGE2_CFLAGS, STAGE3_CFLAGS, and STAGE4_CFLAGS. Add FLAGS_FOR_TARGET and BUILD_CONFIG. (bootstrap_stage): Remove bootstrap-debug custom stages. Turn stage_configureflags, stage_cflags and stage_libcflags into explicit Makefile macros. * Makefile.tpl (HOST_EXPORTS, EXTRA_HOST_FLAGS): Pass GCJ and GFORTRAN. (POSTSTAGE1_HOST_EXPORTS): Add XGCC_FLAGS_FOR_TARGET and TFLAGS to CC. Set CC_FOR_BUILD from CC. (BASE_TARGET_EXPORTS, RAW_CXX_TARGET_EXPORTS, NORMAL_TARGET_EXPORTS): Move SYSROOT_CFLAGS_FOR_TARGET and DEBUG_PREFIX_CFLAGS_FOR_TARGET from CFLAGS and CXXFLAGS to XGCC_FLAGS_FOR_TARGET. Add it along with TFLAGS to CC, CXX, GCJ, and GFORTRAN. (TFLAGS, STAGE_CFLAGS, STAGE_TFLAGS, STAGE_CONFIGURE_FLAGS): New. (_LIBCFLAGS): Renamed to _TFLAGS. (do-compare-debug, do-compare3-debug): Drop. (CC, GCC_FOR_TARGET, CXX_FOR_TARGET, RAW_CXX_FOR_TARGET, GCJ_FOR_TARGET, GFORTRAN_FOR_TARGET): Remove FLAGS_FOR_TARGET. (FLAGS_FOR_TARGET, SYSROOT_CFLAGS_FOR_TARGET, DEBUG_PREFIX_CFLAGS_FOR_TARGET): Move down. (XGCC_FLAGS_FOR_TARGET): New. (BASE_FLAGS_TO_PASS): Pass STAGEid_CFLAGS, STAGEid_TFLAGS and TFLAGS. (EXTRA_HOST_FLAGS): Pass GCJ and GFORTRAN. (POSTSTAGE1_FLAGS_TO_PASS): Move SYSROOT_CFLAGS_FOR_TARGET and DEBUG_PREFIX_CFLAGS_FOR_TARGET from CFLAGS, CXXFLAGS, LIBCFLAGS, LIBCXXFLAGS to XGCC_FLAGS_FOR_TARGET. Add it along with TFLAGS to CC, CXX, GCJ, and GFORTRAN. Pass XGCC_FLAGS_FOR_TARGET and TFLAGS. (BUILD_CONFIG): Include if requested. (all): Set TFLAGS on bootstrap. (configure-stageid-prefixmodule): Pass TFLAGS, adjust FLAGS. (all-stageid-prefixmodule): Likewise. (do-clean, distclean-stageid): Set TFLAGS. (restrap): Fix whitespace. * Makefile.in: Rebuilt. config/ChangeLog: * multi.m4: Save CXX, GFORTRAN and GCJ in config.status. * mt-gnu (CXXFLAGS_FOR_TARGET): Adjust. * bootstrap-O1.mk: New. * bootstrap-O3.mk: New. * bootstrap-debug.mk: New.
69 lines
2.1 KiB
Plaintext
69 lines
2.1 KiB
Plaintext
## -*- Autoconf -*-
|
|
# Copyright (C) 1998, 1999, 2000, 2001, 2003, 2004, 2005, 2006, 2008
|
|
# Free Software Foundation, Inc.
|
|
#
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# serial 6
|
|
|
|
# AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
|
|
# ---------------------------------------------------
|
|
# Add --enable-multilib to configure.
|
|
AC_DEFUN([AM_ENABLE_MULTILIB],
|
|
[# Default to --enable-multilib
|
|
AC_ARG_ENABLE(multilib,
|
|
[ --enable-multilib build many library versions (default)],
|
|
[case "$enableval" in
|
|
yes) multilib=yes ;;
|
|
no) multilib=no ;;
|
|
*) AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
|
|
esac],
|
|
[multilib=yes])
|
|
|
|
# We may get other options which we leave undocumented:
|
|
# --with-target-subdir, --with-multisrctop, --with-multisubdir
|
|
# See config-ml.in if you want the gory details.
|
|
|
|
if test "$srcdir" = "."; then
|
|
if test "$with_target_subdir" != "."; then
|
|
multi_basedir="$srcdir/$with_multisrctop../$2"
|
|
else
|
|
multi_basedir="$srcdir/$with_multisrctop$2"
|
|
fi
|
|
else
|
|
multi_basedir="$srcdir/$2"
|
|
fi
|
|
AC_SUBST(multi_basedir)
|
|
|
|
# Even if the default multilib is not a cross compilation,
|
|
# it may be that some of the other multilibs are.
|
|
if test $cross_compiling = no && test $multilib = yes \
|
|
&& test "x${with_multisubdir}" != x ; then
|
|
cross_compiling=maybe
|
|
fi
|
|
|
|
AC_OUTPUT_COMMANDS([
|
|
# Only add multilib support code if we just rebuilt the top-level
|
|
# Makefile.
|
|
case " $CONFIG_FILES " in
|
|
*" ]m4_default([$1],Makefile)[ "*)
|
|
ac_file=]m4_default([$1],Makefile)[ . ${multi_basedir}/config-ml.in
|
|
;;
|
|
esac],
|
|
[
|
|
srcdir="$srcdir"
|
|
host="$host"
|
|
target="$target"
|
|
with_multisubdir="$with_multisubdir"
|
|
with_multisrctop="$with_multisrctop"
|
|
with_target_subdir="$with_target_subdir"
|
|
ac_configure_args="${multilib_arg} ${ac_configure_args}"
|
|
multi_basedir="$multi_basedir"
|
|
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
|
|
CC="$CC"
|
|
CXX="$CXX"
|
|
GFORTRAN="$GFORTRAN"
|
|
GCJ="$GCJ"])])dnl
|