NeoForge/buildSrc/build.gradle

plugins {
    id 'java-gradle-plugin'
    id 'groovy-gradle-plugin'
}

repositories {
    gradlePluginPortal()
    mavenCentral()
    maven {
        name = "NeoForged"
        url = "https://maven.neoforged.net/releases"
        content {
            includeGroup "codechicken"
            includeGroup "net.neoforged"
        }
    }
    maven {
        name = "MojangMeta"
        url = "https://maven.neoforged.net/mojang-meta"
        content {
            includeModule("net.neoforged", "minecraft-dependencies")
        }
    }
}

dependencies {
    // buildSrc is an includedbuild of the parent directory (gradle.parent)
    // ../settings.gradle sets these version properties accordingly
    implementation "net.neoforged:moddev-gradle:${gradle.parent.ext.moddevgradle_plugin_version}"

    implementation(platform("net.neoforged:minecraft-dependencies:${gradle.parent.ext.minecraft_version}") {
        exclude group: 'org.ow2.asm' // The platform requests a strictly lower version of ASM and we bump it
    })

    implementation "com.google.code.gson:gson"
    implementation "io.codechicken:DiffPatch:${gradle.parent.ext.diffpatch_version}"

    implementation "org.ow2.asm:asm:${gradle.parent.ext.asm_version}"

    implementation "org.apache.maven:maven-artifact:3.9.16"
}