communication_dsoftbus/core/frame/BUILD.gn

# Copyright (c) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/lite/config/component/lite_component.gni")
import("//foundation/communication/dsoftbus/dsoftbus.gni")

if (ohos_kernel_type == "liteos_m") {
  static_library("softbus_server_frame") {
    include_dirs = [
      "include",
      "$dsoftbus_root_path/core/adapter/kernel/include",
      "$dsoftbus_root_path/core/common/message_handler/include",
      "$dsoftbus_root_path/core/common/include",
      "$dsoftbus_root_path/core/common/inner_communication",
      "$dsoftbus_root_path/core/common/softbus_property/include",
      "$dsoftbus_root_path/core/transmission/session/include",
      "$dsoftbus_root_path/core/transmission/trans_channel/manager/include",
      "$dsoftbus_root_path/sdk/bus_center/include",
      "$dsoftbus_root_path/sdk/transmission/trans_channel/manager/include",
      "$dsoftbus_root_path/interfaces/kits",
      "$dsoftbus_root_path/interfaces/kits/bus_center",
      "$dsoftbus_root_path/interfaces/kits/transport",
      "$hilog_lite_include_path",
      "$softbus_adapter_config/spec_config",
    ]

    sources = [
      "$dsoftbus_root_path/core/common/inner_communication/c/softbus_client_interface.c",
      "$dsoftbus_root_path/core/common/inner_communication/c/softbus_server_interface_impl.c",
      "src/softbus_server_frame.c",
      "src/softbus_server_frame_weak.c",
    ]

    deps = [
      "$hilog_lite_deps_path",
      "$dsoftbus_root_path/core/common/log:softbus_log",
    ]
  }
} else {
  shared_library("softbus_server_frame") {
    include_dirs = [
      "common/include",
      "small/init/include",
      "small/client_manager/include",
      "$dsoftbus_root_path/core/adapter/kernel/include",
      "$dsoftbus_root_path/core/common/message_handler/include",
      "$dsoftbus_root_path/core/common/include",
      "$dsoftbus_root_path/core/common/inner_communication",
      "$dsoftbus_root_path/core/connection/interface",
      "$dsoftbus_root_path/core/connection/manager",
      "$dsoftbus_root_path/core/transmission/trans_channel/proxy/include",
      "$dsoftbus_root_path/core/transmission/common/include",
      "$dsoftbus_root_path/core/common/softbus_property/include",
      "$dsoftbus_root_path/interfaces/kits/transport",
      "//base/security/deviceauth/interfaces/innerkits",
      "//utils/native/lite/include",
      "$hilog_lite_include_path",
      "$softbus_adapter_config/spec_config",
    ]

    sources = [
      "common/src/softbus_server_frame.c",
      "small/init/src/bus_center_server_stub.c",
      "small/init/src/disc_server_stub.c",
      "small/init/src/softbus_server_stub.c",
      "small/init/src/trans_server_stub.c",
    ]

    cflags = [
      "-Wall",
      "-fPIC",
      "-std=c99",
    ]

    deps = [
      "$dsoftbus_root_path/core/adapter/kernel:softbus_adapter_kernel",
      "$dsoftbus_root_path/core/authentication:dsoftbus_auth_server",
      "$dsoftbus_root_path/core/bus_center:dsoftbus_bus_center_server",
      "$dsoftbus_root_path/core/common/message_handler:message_handler",
      "$dsoftbus_root_path/core/common/security/permission:softbus_permission",
      "$dsoftbus_root_path/core/common/utils:softbus_utils",
      "$dsoftbus_root_path/core/common/log:softbus_log",
      "$dsoftbus_root_path/core/connection:softbus_connection",
      "$dsoftbus_root_path/core/discovery:dsoftbus_disc_server",
      "$dsoftbus_root_path/core/frame/small/client_manager:client_manager",
      "$dsoftbus_root_path/core/transmission/session:dsoftbus_trans_session",
      "$hilog_lite_deps_path",
      "//foundation/communication/ipc_lite:liteipc_adapter",
      "//foundation/distributedschedule/samgr_lite/samgr:samgr",
      "$dsoftbus_root_path/core/bus_center/service:dsoftbus_bus_center_service",
    ]
  }
  executable("softbus_server") {
    sources = [ "small/init/src/softbus_server_main.c" ]
    include_dirs = [ "common/include" ]
    deps = [ ":softbus_server_frame" ]
  }
}