startup_appspawn/BUILD.gn

# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//base/startup/appspawn_standard/appspawn.gni")
import("//build/ohos.gni")

config("appspawn_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "common",
    "standard",
    "adapter",
    "interfaces/innerkits/include",
    "//utils/native/base/include",
    "${aafwk_path}/frameworks/kits/appkit/native/app/include",
    "${aafwk_path}/interfaces/innerkits/app_manager/include/appmgr",
    "${appexecfwk_path}/interfaces/innerkits/libeventhandler/include",
    "${appexecfwk_path}/common/log/include",
    "${appexecfwk_path}/interfaces/innerkits/appexecfwk_core/include/bundlemgr",
    "${appexecfwk_path}/interfaces/innerkits/appexecfwk_base/include",
    "${aafwk_path}/interfaces/innerkits/want/include/ohos/aafwk/content",
    "${aafwk_path}/interfaces/innerkits/want/include",
    "${aafwk_path}/interfaces/innerkits/ability_manager/include",
    "${aafwk_path}/interfaces/innerkits/base/include",
    "${aafwk_path}/frameworks/kits/ability/native/include",
    "${aafwk_path}/services/abilitymgr/include",
    "//base/global/resmgr_standard/interfaces/innerkits/include",
    "//base/security/access_token/interfaces/innerkits/token_setproc/include",
    "//base/startup/init_lite/services/log",
    "//base/startup/init_lite/services/include",
    "//base/startup/init_lite/services/loopevent/include",
    "//base/startup/init_lite/interfaces/innerkits/include",
    "//base/startup/init_lite/interfaces/innerkits/sandbox/include",
    "//base/startup/syspara_lite/interfaces/innerkits/native/syspara/include",
  ]

  if (build_selinux) {
    cflags = [ "-DWITH_SELINUX" ]
  }
}

ohos_executable("appspawn") {
  sources = [
    "${appspawn_path}/adapter/appspawn_ace.cpp",
    "${appspawn_path}/standard/main.c",
  ]
  configs = [ ":appspawn_config" ]
  deps = [
    "${appspawn_path}:appspawn_server",
    "//foundation/aafwk/standard/frameworks/kits/appkit:appkit_native",
  ]
  external_deps = [
    "ability_base:want",
    "ability_runtime:app_manager",
    "hiviewdfx_hilog_native:libhilog",
    "ipc:ipc_core",
    "utils_base:utils",
  ]

  install_enable = true
  subsystem_name = "${subsystem_name}"
  part_name = "${part_name}"
}

ohos_static_library("appspawn_server") {
  sources = [
    "${appspawn_path}/adapter/appspawn_adapter.cpp",
    "${appspawn_path}/adapter/appspawn_log.cpp",
    "${appspawn_path}/adapter/appspawn_sandbox.cpp",
    "${appspawn_path}/common/appspawn_server.c",
    "${appspawn_path}/standard/appspawn_process.c",
    "${appspawn_path}/standard/appspawn_service.c",
  ]
  defines = [
    "GRAPHIC_PERMISSION_CHECK",
    "INIT_AGENT",
  ]
  configs = [ ":appspawn_config" ]
  ldflags = [ "-Wl,--dynamic-linker,/system/bin/linker64z" ]
  deps = [
    "//base/security/access_token/interfaces/innerkits/token_setproc:libtoken_setproc",
    "//base/startup/init_lite/interfaces/innerkits:libbegetutil",
    "//base/startup/init_lite/interfaces/innerkits/sandbox:libsandbox",
    "//base/startup/init_lite/services/loopevent:loopevent",
    "//base/startup/init_lite/services/utils:libinit_tools",
    "//base/startup/syspara_lite/interfaces/innerkits/native/syspara:syspara",
    "//third_party/libuv:uv_static",
    "//utils/native/base:utils",
  ]
  external_deps = [ "hiviewdfx_hilog_native:libhilog" ]
  if (build_selinux) {
    external_deps += [ "selinux:libhap_restorecon" ]
  }

  subsystem_name = "${subsystem_name}"
  part_name = "${part_name}"
}

ohos_prebuilt_etc("appspawn.rc") {
  source = "appspawn.cfg"
  relative_install_dir = "init"
  subsystem_name = "${subsystem_name}"
  part_name = "${part_name}"
}

ohos_executable("nwebspawn") {
  defines = [ "NWEB_SPAWN" ]
  sources = [
    "${appspawn_path}/adapter/appspawn_nweb.cpp",
    "${appspawn_path}/standard/main.c",
  ]
  configs = [ ":appspawn_config" ]
  deps = [
    "${appspawn_path}:appspawn_server",
    "//base/startup/init_lite/interfaces/innerkits/sandbox:libsandbox",
  ]

  install_enable = true
  subsystem_name = "${subsystem_name}"
  part_name = "${part_name}"
}

ohos_prebuilt_etc("nwebspawn.rc") {
  source = "nwebspawn.cfg"
  relative_install_dir = "init"
  subsystem_name = "${subsystem_name}"
  part_name = "${part_name}"
}

group("nweb") {
  deps = []
  if (appspawn_support_nweb) {
    deps += [
      ":nwebspawn",
      ":nwebspawn.rc",
    ]
  }
}