mirror of
https://github.com/openharmony/third_party_cmake.git
synced 2026-07-01 09:24:50 -04:00
Kitware Robot
77543bde41
Ancient CMake versions required upper-case commands. Later command
names became case-insensitive. Now the preferred style is lower-case.
Run the following shell code:
cmake --help-command-list |
grep -v "cmake version" |
while read c; do
echo 's/\b'"$(echo $c | tr '[:lower:]' '[:upper:]')"'\(\s*\)(/'"$c"'\1(/g'
done >convert.sed &&
git ls-files -z -- bootstrap '*.cmake' '*.cmake.in' '*CMakeLists.txt' |
egrep -z -v '^(Utilities/cm|Source/kwsys/)' |
xargs -0 sed -i -f convert.sed &&
rm convert.sed
62 lines
2.7 KiB
CMake
62 lines
2.7 KiB
CMake
# This module defines two macros:
|
|
# CMAKE_PUSH_CHECK_STATE()
|
|
# and
|
|
# CMAKE_POP_CHECK_STATE()
|
|
# These two macros can be used to save and restore the state of the variables
|
|
# CMAKE_REQUIRED_FLAGS, CMAKE_REQUIRED_DEFINITIONS, CMAKE_REQUIRED_LIBRARIES
|
|
# and CMAKE_REQUIRED_INCLUDES used by the various Check-files coming with CMake,
|
|
# like e.g. check_function_exists() etc.
|
|
# The variable contents are pushed on a stack, pushing multiple times is supported.
|
|
# This is useful e.g. when executing such tests in a Find-module, where they have to be set,
|
|
# but after the Find-module has been executed they should have the same value
|
|
# as they had before.
|
|
#
|
|
# Usage:
|
|
# cmake_push_check_state()
|
|
# set(CMAKE_REQUIRED_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS} -DSOME_MORE_DEF)
|
|
# check_function_exists(...)
|
|
# cmake_pop_check_state()
|
|
|
|
#=============================================================================
|
|
# Copyright 2006-2011 Alexander Neundorf, <neundorf@kde.org>
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
|
|
macro(CMAKE_PUSH_CHECK_STATE)
|
|
|
|
if(NOT DEFINED _CMAKE_PUSH_CHECK_STATE_COUNTER)
|
|
set(_CMAKE_PUSH_CHECK_STATE_COUNTER 0)
|
|
endif()
|
|
|
|
math(EXPR _CMAKE_PUSH_CHECK_STATE_COUNTER "${_CMAKE_PUSH_CHECK_STATE_COUNTER}+1")
|
|
|
|
set(_CMAKE_REQUIRED_INCLUDES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER} ${CMAKE_REQUIRED_INCLUDES})
|
|
set(_CMAKE_REQUIRED_DEFINITIONS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER} ${CMAKE_REQUIRED_DEFINITIONS})
|
|
set(_CMAKE_REQUIRED_LIBRARIES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER} ${CMAKE_REQUIRED_LIBRARIES})
|
|
set(_CMAKE_REQUIRED_FLAGS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER} ${CMAKE_REQUIRED_FLAGS})
|
|
endmacro(CMAKE_PUSH_CHECK_STATE)
|
|
|
|
macro(CMAKE_POP_CHECK_STATE)
|
|
|
|
# don't pop more than we pushed
|
|
if("${_CMAKE_PUSH_CHECK_STATE_COUNTER}" GREATER "0")
|
|
|
|
set(CMAKE_REQUIRED_INCLUDES ${_CMAKE_REQUIRED_INCLUDES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
|
|
set(CMAKE_REQUIRED_DEFINITIONS ${_CMAKE_REQUIRED_DEFINITIONS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
|
|
set(CMAKE_REQUIRED_LIBRARIES ${_CMAKE_REQUIRED_LIBRARIES_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
|
|
set(CMAKE_REQUIRED_FLAGS ${_CMAKE_REQUIRED_FLAGS_SAVE_${_CMAKE_PUSH_CHECK_STATE_COUNTER}})
|
|
|
|
math(EXPR _CMAKE_PUSH_CHECK_STATE_COUNTER "${_CMAKE_PUSH_CHECK_STATE_COUNTER}-1")
|
|
endif()
|
|
|
|
endmacro(CMAKE_POP_CHECK_STATE)
|