mirror of
https://github.com/reactos/CMake.git
synced 2024-11-24 12:09:48 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
53 lines
1.9 KiB
CMake
53 lines
1.9 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# CheckCCompilerFlag
|
|
# ------------------
|
|
#
|
|
# Check whether the C compiler supports a given flag.
|
|
#
|
|
# CHECK_C_COMPILER_FLAG(<flag> <var>)
|
|
#
|
|
# ::
|
|
#
|
|
# <flag> - the compiler flag
|
|
# <var> - variable to store the result
|
|
# Will be created as an internal cache variable.
|
|
#
|
|
# This internally calls the check_c_source_compiles macro and sets
|
|
# CMAKE_REQUIRED_DEFINITIONS to <flag>. See help for
|
|
# CheckCSourceCompiles for a listing of variables that can otherwise
|
|
# modify the build. The result only tells that the compiler does not
|
|
# give an error message when it encounters the flag. If the flag has
|
|
# any effect or even a specific one is beyond the scope of this module.
|
|
|
|
include(CheckCSourceCompiles)
|
|
include(CMakeCheckCompilerFlagCommonPatterns)
|
|
|
|
macro (CHECK_C_COMPILER_FLAG _FLAG _RESULT)
|
|
set(SAFE_CMAKE_REQUIRED_DEFINITIONS "${CMAKE_REQUIRED_DEFINITIONS}")
|
|
set(CMAKE_REQUIRED_DEFINITIONS "${_FLAG}")
|
|
|
|
# Normalize locale during test compilation.
|
|
set(_CheckCCompilerFlag_LOCALE_VARS LC_ALL LC_MESSAGES LANG)
|
|
foreach(v ${_CheckCCompilerFlag_LOCALE_VARS})
|
|
set(_CheckCCompilerFlag_SAVED_${v} "$ENV{${v}}")
|
|
set(ENV{${v}} C)
|
|
endforeach()
|
|
CHECK_COMPILER_FLAG_COMMON_PATTERNS(_CheckCCompilerFlag_COMMON_PATTERNS)
|
|
CHECK_C_SOURCE_COMPILES("int main(void) { return 0; }" ${_RESULT}
|
|
# Some compilers do not fail with a bad flag
|
|
FAIL_REGEX "command line option .* is valid for .* but not for C" # GNU
|
|
${_CheckCCompilerFlag_COMMON_PATTERNS}
|
|
)
|
|
foreach(v ${_CheckCCompilerFlag_LOCALE_VARS})
|
|
set(ENV{${v}} ${_CheckCCompilerFlag_SAVED_${v}})
|
|
unset(_CheckCCompilerFlag_SAVED_${v})
|
|
endforeach()
|
|
unset(_CheckCCompilerFlag_LOCALE_VARS)
|
|
unset(_CheckCCompilerFlag_COMMON_PATTERNS)
|
|
|
|
set (CMAKE_REQUIRED_DEFINITIONS "${SAFE_CMAKE_REQUIRED_DEFINITIONS}")
|
|
endmacro ()
|