mirror of
https://github.com/reactos/CMake.git
synced 2024-12-13 22:58:41 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
89 lines
3.2 KiB
CMake
89 lines
3.2 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# CheckIncludeFileCXX
|
|
# -------------------
|
|
#
|
|
# Provides a macro to check if a header file can be included in ``CXX``.
|
|
#
|
|
# .. command:: CHECK_INCLUDE_FILE_CXX
|
|
#
|
|
# ::
|
|
#
|
|
# CHECK_INCLUDE_FILE_CXX(<include> <variable> [<flags>])
|
|
#
|
|
# Check if the given ``<include>`` file may be included in a ``CXX``
|
|
# source file and store the result in an internal cache entry named
|
|
# ``<variable>``. The optional third argument may be used to add
|
|
# compilation flags to the check (or use ``CMAKE_REQUIRED_FLAGS`` below).
|
|
#
|
|
# The following variables may be set before calling this macro to modify
|
|
# the way the check is run:
|
|
#
|
|
# ``CMAKE_REQUIRED_FLAGS``
|
|
# string of compile command line flags
|
|
# ``CMAKE_REQUIRED_DEFINITIONS``
|
|
# list of macros to define (-DFOO=bar)
|
|
# ``CMAKE_REQUIRED_INCLUDES``
|
|
# list of include directories
|
|
# ``CMAKE_REQUIRED_QUIET``
|
|
# execute quietly without messages
|
|
#
|
|
# See modules :module:`CheckIncludeFile` and :module:`CheckIncludeFiles`
|
|
# to check for one or more ``C`` headers.
|
|
|
|
macro(CHECK_INCLUDE_FILE_CXX INCLUDE VARIABLE)
|
|
if(NOT DEFINED "${VARIABLE}" OR "x${${VARIABLE}}" STREQUAL "x${VARIABLE}")
|
|
if(CMAKE_REQUIRED_INCLUDES)
|
|
set(CHECK_INCLUDE_FILE_CXX_INCLUDE_DIRS "-DINCLUDE_DIRECTORIES=${CMAKE_REQUIRED_INCLUDES}")
|
|
else()
|
|
set(CHECK_INCLUDE_FILE_CXX_INCLUDE_DIRS)
|
|
endif()
|
|
set(MACRO_CHECK_INCLUDE_FILE_FLAGS ${CMAKE_REQUIRED_FLAGS})
|
|
set(CHECK_INCLUDE_FILE_VAR ${INCLUDE})
|
|
configure_file(${CMAKE_ROOT}/Modules/CheckIncludeFile.cxx.in
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/CheckIncludeFile.cxx)
|
|
if(NOT CMAKE_REQUIRED_QUIET)
|
|
message(STATUS "Looking for C++ include ${INCLUDE}")
|
|
endif()
|
|
if(${ARGC} EQUAL 3)
|
|
set(CMAKE_CXX_FLAGS_SAVE ${CMAKE_CXX_FLAGS})
|
|
string(APPEND CMAKE_CXX_FLAGS " ${ARGV2}")
|
|
endif()
|
|
|
|
try_compile(${VARIABLE}
|
|
${CMAKE_BINARY_DIR}
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/CheckIncludeFile.cxx
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
CMAKE_FLAGS
|
|
-DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_INCLUDE_FILE_FLAGS}
|
|
"${CHECK_INCLUDE_FILE_CXX_INCLUDE_DIRS}"
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
|
|
if(${ARGC} EQUAL 3)
|
|
set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS_SAVE})
|
|
endif()
|
|
|
|
if(${VARIABLE})
|
|
if(NOT CMAKE_REQUIRED_QUIET)
|
|
message(STATUS "Looking for C++ include ${INCLUDE} - found")
|
|
endif()
|
|
set(${VARIABLE} 1 CACHE INTERNAL "Have include ${INCLUDE}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the include file ${INCLUDE} "
|
|
"exists passed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
else()
|
|
if(NOT CMAKE_REQUIRED_QUIET)
|
|
message(STATUS "Looking for C++ include ${INCLUDE} - not found")
|
|
endif()
|
|
set(${VARIABLE} "" CACHE INTERNAL "Have include ${INCLUDE}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the include file ${INCLUDE} "
|
|
"exists failed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
endif()
|
|
endif()
|
|
endmacro()
|