mirror of
https://github.com/reactos/CMake.git
synced 2024-12-13 22:58:41 +00:00
35c48e1270
Add the function cmake_expand_imported_targets() to expand imported targets in a list of libraries into their on-disk file names for a particular configuration. Adapt the implementation from KDE's HANDLE_IMPORTED_TARGETS_IN_CMAKE_REQUIRED_LIBRARIES which has been in use for over 2 years. Call the function from all the Check*.cmake macros to handle imported targets named in CMAKE_REQUIRED_LIBRARIES. Alex
92 lines
4.2 KiB
CMake
92 lines
4.2 KiB
CMake
# - Check if the given C++ source code compiles and runs.
|
|
# CHECK_CXX_SOURCE_RUNS(<code> <var>)
|
|
# <code> - source code to try to compile
|
|
# <var> - variable to store the result
|
|
# (1 for success, empty for failure)
|
|
# The following variables may be set before calling this macro to
|
|
# modify the way the check is run:
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_INCLUDES = list of include directories
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
|
|
|
#=============================================================================
|
|
# Copyright 2006-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
INCLUDE("${CMAKE_CURRENT_LIST_DIR}/CMakeExpandImportedTargets.cmake")
|
|
|
|
|
|
MACRO(CHECK_CXX_SOURCE_RUNS SOURCE VAR)
|
|
IF("${VAR}" MATCHES "^${VAR}$")
|
|
SET(MACRO_CHECK_FUNCTION_DEFINITIONS
|
|
"-D${VAR} ${CMAKE_REQUIRED_FLAGS}")
|
|
IF(CMAKE_REQUIRED_LIBRARIES)
|
|
# this one translates potentially used imported library targets to their files on disk
|
|
CMAKE_EXPAND_IMPORTED_TARGETS(_ADJUSTED_CMAKE_REQUIRED_LIBRARIES LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CONFIGURATION "${CMAKE_TRY_COMPILE_CONFIGURATION}")
|
|
SET(CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES
|
|
"-DLINK_LIBRARIES:STRING=${_ADJUSTED_CMAKE_REQUIRED_LIBRARIES}")
|
|
ELSE(CMAKE_REQUIRED_LIBRARIES)
|
|
SET(CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES)
|
|
ENDIF(CMAKE_REQUIRED_LIBRARIES)
|
|
IF(CMAKE_REQUIRED_INCLUDES)
|
|
SET(CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES
|
|
"-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}")
|
|
ELSE(CMAKE_REQUIRED_INCLUDES)
|
|
SET(CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES)
|
|
ENDIF(CMAKE_REQUIRED_INCLUDES)
|
|
FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.cxx"
|
|
"${SOURCE}\n")
|
|
|
|
MESSAGE(STATUS "Performing Test ${VAR}")
|
|
TRY_RUN(${VAR}_EXITCODE ${VAR}_COMPILED
|
|
${CMAKE_BINARY_DIR}
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.cxx
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
|
|
-DCMAKE_SKIP_RPATH:BOOL=${CMAKE_SKIP_RPATH}
|
|
"${CHECK_CXX_SOURCE_COMPILES_ADD_LIBRARIES}"
|
|
"${CHECK_CXX_SOURCE_COMPILES_ADD_INCLUDES}"
|
|
COMPILE_OUTPUT_VARIABLE OUTPUT)
|
|
|
|
# if it did not compile make the return value fail code of 1
|
|
IF(NOT ${VAR}_COMPILED)
|
|
SET(${VAR}_EXITCODE 1)
|
|
ENDIF(NOT ${VAR}_COMPILED)
|
|
# if the return value was 0 then it worked
|
|
IF("${${VAR}_EXITCODE}" EQUAL 0)
|
|
SET(${VAR} 1 CACHE INTERNAL "Test ${VAR}")
|
|
MESSAGE(STATUS "Performing Test ${VAR} - Success")
|
|
FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Performing C++ SOURCE FILE Test ${VAR} succeded with the following output:\n"
|
|
"${OUTPUT}\n"
|
|
"Return value: ${${VAR}}\n"
|
|
"Source file was:\n${SOURCE}\n")
|
|
ELSE("${${VAR}_EXITCODE}" EQUAL 0)
|
|
IF(CMAKE_CROSSCOMPILING AND "${${VAR}_EXITCODE}" MATCHES "FAILED_TO_RUN")
|
|
SET(${VAR} "${${VAR}_EXITCODE}")
|
|
ELSE(CMAKE_CROSSCOMPILING AND "${${VAR}_EXITCODE}" MATCHES "FAILED_TO_RUN")
|
|
SET(${VAR} "" CACHE INTERNAL "Test ${VAR}")
|
|
ENDIF(CMAKE_CROSSCOMPILING AND "${${VAR}_EXITCODE}" MATCHES "FAILED_TO_RUN")
|
|
|
|
MESSAGE(STATUS "Performing Test ${VAR} - Failed")
|
|
FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Performing C++ SOURCE FILE Test ${VAR} failed with the following output:\n"
|
|
"${OUTPUT}\n"
|
|
"Return value: ${${VAR}_EXITCODE}\n"
|
|
"Source file was:\n${SOURCE}\n")
|
|
ENDIF("${${VAR}_EXITCODE}" EQUAL 0)
|
|
ENDIF("${VAR}" MATCHES "^${VAR}$")
|
|
ENDMACRO(CHECK_CXX_SOURCE_RUNS)
|
|
|