mirror of
https://github.com/reactos/CMake.git
synced 2024-12-13 22:58:41 +00:00
35c48e1270
Add the function cmake_expand_imported_targets() to expand imported targets in a list of libraries into their on-disk file names for a particular configuration. Adapt the implementation from KDE's HANDLE_IMPORTED_TARGETS_IN_CMAKE_REQUIRED_LIBRARIES which has been in use for over 2 years. Call the function from all the Check*.cmake macros to handle imported targets named in CMAKE_REQUIRED_LIBRARIES. Alex
71 lines
3.2 KiB
CMake
71 lines
3.2 KiB
CMake
# - Check if the function exists.
|
|
# CHECK_LIBRARY_EXISTS (LIBRARY FUNCTION LOCATION VARIABLE)
|
|
#
|
|
# LIBRARY - the name of the library you are looking for
|
|
# FUNCTION - the name of the function
|
|
# LOCATION - location where the library should be found
|
|
# VARIABLE - variable to store the result
|
|
#
|
|
# The following variables may be set before calling this macro to
|
|
# modify the way the check is run:
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
|
|
|
#=============================================================================
|
|
# Copyright 2002-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
INCLUDE("${CMAKE_CURRENT_LIST_DIR}/CMakeExpandImportedTargets.cmake")
|
|
|
|
|
|
MACRO(CHECK_LIBRARY_EXISTS LIBRARY FUNCTION LOCATION VARIABLE)
|
|
IF("${VARIABLE}" MATCHES "^${VARIABLE}$")
|
|
SET(MACRO_CHECK_LIBRARY_EXISTS_DEFINITION
|
|
"-DCHECK_FUNCTION_EXISTS=${FUNCTION} ${CMAKE_REQUIRED_FLAGS}")
|
|
MESSAGE(STATUS "Looking for ${FUNCTION} in ${LIBRARY}")
|
|
SET(CHECK_LIBRARY_EXISTS_LIBRARIES ${LIBRARY})
|
|
IF(CMAKE_REQUIRED_LIBRARIES)
|
|
# this one translates potentially used imported library targets to their files on disk
|
|
CMAKE_EXPAND_IMPORTED_TARGETS(_ADJUSTED_CMAKE_REQUIRED_LIBRARIES LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CONFIGURATION "${CMAKE_TRY_COMPILE_CONFIGURATION}")
|
|
SET(CHECK_LIBRARY_EXISTS_LIBRARIES
|
|
${CHECK_LIBRARY_EXISTS_LIBRARIES} ${_ADJUSTED_CMAKE_REQUIRED_LIBRARIES})
|
|
ENDIF(CMAKE_REQUIRED_LIBRARIES)
|
|
TRY_COMPILE(${VARIABLE}
|
|
${CMAKE_BINARY_DIR}
|
|
${CMAKE_ROOT}/Modules/CheckFunctionExists.c
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
CMAKE_FLAGS
|
|
-DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_LIBRARY_EXISTS_DEFINITION}
|
|
-DLINK_DIRECTORIES:STRING=${LOCATION}
|
|
"-DLINK_LIBRARIES:STRING=${CHECK_LIBRARY_EXISTS_LIBRARIES}"
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
|
|
IF(${VARIABLE})
|
|
MESSAGE(STATUS "Looking for ${FUNCTION} in ${LIBRARY} - found")
|
|
SET(${VARIABLE} 1 CACHE INTERNAL "Have library ${LIBRARY}")
|
|
FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the function ${FUNCTION} exists in the ${LIBRARY} "
|
|
"passed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
ELSE(${VARIABLE})
|
|
MESSAGE(STATUS "Looking for ${FUNCTION} in ${LIBRARY} - not found")
|
|
SET(${VARIABLE} "" CACHE INTERNAL "Have library ${LIBRARY}")
|
|
FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the function ${FUNCTION} exists in the ${LIBRARY} "
|
|
"failed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
ENDIF(${VARIABLE})
|
|
ENDIF("${VARIABLE}" MATCHES "^${VARIABLE}$")
|
|
ENDMACRO(CHECK_LIBRARY_EXISTS)
|