mirror of
https://github.com/reactos/CMake.git
synced 2024-11-25 12:40:06 +00:00
35c48e1270
Add the function cmake_expand_imported_targets() to expand imported targets in a list of libraries into their on-disk file names for a particular configuration. Adapt the implementation from KDE's HANDLE_IMPORTED_TARGETS_IN_CMAKE_REQUIRED_LIBRARIES which has been in use for over 2 years. Call the function from all the Check*.cmake macros to handle imported targets named in CMAKE_REQUIRED_LIBRARIES. Alex
96 lines
3.9 KiB
CMake
96 lines
3.9 KiB
CMake
# - Check if given C source compiles and links into an executable
|
|
# CHECK_C_SOURCE_COMPILES(<code> <var> [FAIL_REGEX <fail-regex>])
|
|
# <code> - source code to try to compile, must define 'main'
|
|
# <var> - variable to store whether the source code compiled
|
|
# <fail-regex> - fail if test output matches this regex
|
|
# The following variables may be set before calling this macro to
|
|
# modify the way the check is run:
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_INCLUDES = list of include directories
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
|
|
|
#=============================================================================
|
|
# Copyright 2005-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
INCLUDE("${CMAKE_CURRENT_LIST_DIR}/CMakeExpandImportedTargets.cmake")
|
|
|
|
|
|
MACRO(CHECK_C_SOURCE_COMPILES SOURCE VAR)
|
|
IF("${VAR}" MATCHES "^${VAR}$")
|
|
SET(_FAIL_REGEX)
|
|
SET(_key)
|
|
FOREACH(arg ${ARGN})
|
|
IF("${arg}" MATCHES "^(FAIL_REGEX)$")
|
|
SET(_key "${arg}")
|
|
ELSEIF(_key)
|
|
LIST(APPEND _${_key} "${arg}")
|
|
ELSE()
|
|
MESSAGE(FATAL_ERROR "Unknown argument:\n ${arg}\n")
|
|
ENDIF()
|
|
ENDFOREACH()
|
|
SET(MACRO_CHECK_FUNCTION_DEFINITIONS
|
|
"-D${VAR} ${CMAKE_REQUIRED_FLAGS}")
|
|
IF(CMAKE_REQUIRED_LIBRARIES)
|
|
# this one translates potentially used imported library targets to their files on disk
|
|
CMAKE_EXPAND_IMPORTED_TARGETS(_ADJUSTED_CMAKE_REQUIRED_LIBRARIES LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CONFIGURATION "${CMAKE_TRY_COMPILE_CONFIGURATION}")
|
|
SET(CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES
|
|
"-DLINK_LIBRARIES:STRING=${_ADJUSTED_CMAKE_REQUIRED_LIBRARIES}")
|
|
ELSE(CMAKE_REQUIRED_LIBRARIES)
|
|
SET(CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES)
|
|
ENDIF(CMAKE_REQUIRED_LIBRARIES)
|
|
IF(CMAKE_REQUIRED_INCLUDES)
|
|
SET(CHECK_C_SOURCE_COMPILES_ADD_INCLUDES
|
|
"-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}")
|
|
ELSE(CMAKE_REQUIRED_INCLUDES)
|
|
SET(CHECK_C_SOURCE_COMPILES_ADD_INCLUDES)
|
|
ENDIF(CMAKE_REQUIRED_INCLUDES)
|
|
FILE(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.c"
|
|
"${SOURCE}\n")
|
|
|
|
MESSAGE(STATUS "Performing Test ${VAR}")
|
|
TRY_COMPILE(${VAR}
|
|
${CMAKE_BINARY_DIR}
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.c
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
|
|
"${CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES}"
|
|
"${CHECK_C_SOURCE_COMPILES_ADD_INCLUDES}"
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
|
|
FOREACH(_regex ${_FAIL_REGEX})
|
|
IF("${OUTPUT}" MATCHES "${_regex}")
|
|
SET(${VAR} 0)
|
|
ENDIF()
|
|
ENDFOREACH()
|
|
|
|
IF(${VAR})
|
|
SET(${VAR} 1 CACHE INTERNAL "Test ${VAR}")
|
|
MESSAGE(STATUS "Performing Test ${VAR} - Success")
|
|
FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Performing C SOURCE FILE Test ${VAR} succeded with the following output:\n"
|
|
"${OUTPUT}\n"
|
|
"Source file was:\n${SOURCE}\n")
|
|
ELSE(${VAR})
|
|
MESSAGE(STATUS "Performing Test ${VAR} - Failed")
|
|
SET(${VAR} "" CACHE INTERNAL "Test ${VAR}")
|
|
FILE(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Performing C SOURCE FILE Test ${VAR} failed with the following output:\n"
|
|
"${OUTPUT}\n"
|
|
"Source file was:\n${SOURCE}\n")
|
|
ENDIF(${VAR})
|
|
ENDIF("${VAR}" MATCHES "^${VAR}$")
|
|
ENDMACRO(CHECK_C_SOURCE_COMPILES)
|
|
|