mirror of
https://github.com/reactos/CMake.git
synced 2024-12-13 22:58:41 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
102 lines
4.2 KiB
CMake
102 lines
4.2 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
|
|
if(CMAKE_Fortran_COMPILER_FORCED)
|
|
# The compiler configuration was forced by the user.
|
|
# Assume the user has configured all compiler information.
|
|
set(CMAKE_Fortran_COMPILER_WORKS TRUE)
|
|
return()
|
|
endif()
|
|
|
|
include(CMakeTestCompilerCommon)
|
|
|
|
# Remove any cached result from an older CMake version.
|
|
# We now store this in CMakeFortranCompiler.cmake.
|
|
unset(CMAKE_Fortran_COMPILER_WORKS CACHE)
|
|
|
|
# This file is used by EnableLanguage in cmGlobalGenerator to
|
|
# determine that that selected Fortran compiler can actually compile
|
|
# and link the most basic of programs. If not, a fatal error
|
|
# is set and cmake stops processing commands and will not generate
|
|
# any makefiles or projects.
|
|
if(NOT CMAKE_Fortran_COMPILER_WORKS)
|
|
PrintTestCompilerStatus("Fortran" "")
|
|
file(WRITE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testFortranCompiler.f "
|
|
PROGRAM TESTFortran
|
|
PRINT *, 'Hello'
|
|
END
|
|
")
|
|
try_compile(CMAKE_Fortran_COMPILER_WORKS ${CMAKE_BINARY_DIR}
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testFortranCompiler.f
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
# Move result from cache to normal variable.
|
|
set(CMAKE_Fortran_COMPILER_WORKS ${CMAKE_Fortran_COMPILER_WORKS})
|
|
unset(CMAKE_Fortran_COMPILER_WORKS CACHE)
|
|
set(FORTRAN_TEST_WAS_RUN 1)
|
|
endif()
|
|
|
|
if(NOT CMAKE_Fortran_COMPILER_WORKS)
|
|
PrintTestCompilerStatus("Fortran" " -- broken")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the Fortran compiler works failed with "
|
|
"the following output:\n${OUTPUT}\n\n")
|
|
message(FATAL_ERROR "The Fortran compiler \"${CMAKE_Fortran_COMPILER}\" "
|
|
"is not able to compile a simple test program.\nIt fails "
|
|
"with the following output:\n ${OUTPUT}\n\n"
|
|
"CMake will not be able to correctly generate this project.")
|
|
else()
|
|
if(FORTRAN_TEST_WAS_RUN)
|
|
PrintTestCompilerStatus("Fortran" " -- works")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the Fortran compiler works passed with "
|
|
"the following output:\n${OUTPUT}\n\n")
|
|
endif()
|
|
|
|
# Try to identify the ABI and configure it into CMakeFortranCompiler.cmake
|
|
include(${CMAKE_ROOT}/Modules/CMakeDetermineCompilerABI.cmake)
|
|
CMAKE_DETERMINE_COMPILER_ABI(Fortran ${CMAKE_ROOT}/Modules/CMakeFortranCompilerABI.F)
|
|
|
|
# Test for Fortran 90 support by using an f90-specific construct.
|
|
if(NOT DEFINED CMAKE_Fortran_COMPILER_SUPPORTS_F90)
|
|
message(STATUS "Checking whether ${CMAKE_Fortran_COMPILER} supports Fortran 90")
|
|
file(WRITE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testFortranCompilerF90.f90 "
|
|
PROGRAM TESTFortran90
|
|
integer stop ; stop = 1 ; do while ( stop .eq. 0 ) ; end do
|
|
END PROGRAM TESTFortran90
|
|
")
|
|
try_compile(CMAKE_Fortran_COMPILER_SUPPORTS_F90 ${CMAKE_BINARY_DIR}
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testFortranCompilerF90.f90
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
if(CMAKE_Fortran_COMPILER_SUPPORTS_F90)
|
|
message(STATUS "Checking whether ${CMAKE_Fortran_COMPILER} supports Fortran 90 -- yes")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the Fortran compiler supports Fortran 90 passed with "
|
|
"the following output:\n${OUTPUT}\n\n")
|
|
set(CMAKE_Fortran_COMPILER_SUPPORTS_F90 1)
|
|
else()
|
|
message(STATUS "Checking whether ${CMAKE_Fortran_COMPILER} supports Fortran 90 -- no")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the Fortran compiler supports Fortran 90 failed with "
|
|
"the following output:\n${OUTPUT}\n\n")
|
|
set(CMAKE_Fortran_COMPILER_SUPPORTS_F90 0)
|
|
endif()
|
|
unset(CMAKE_Fortran_COMPILER_SUPPORTS_F90 CACHE)
|
|
endif()
|
|
|
|
# Re-configure to save learned information.
|
|
configure_file(
|
|
${CMAKE_ROOT}/Modules/CMakeFortranCompiler.cmake.in
|
|
${CMAKE_PLATFORM_INFO_DIR}/CMakeFortranCompiler.cmake
|
|
@ONLY
|
|
)
|
|
include(${CMAKE_PLATFORM_INFO_DIR}/CMakeFortranCompiler.cmake)
|
|
|
|
if(CMAKE_Fortran_SIZEOF_DATA_PTR)
|
|
foreach(f ${CMAKE_Fortran_ABI_FILES})
|
|
include(${f})
|
|
endforeach()
|
|
unset(CMAKE_Fortran_ABI_FILES)
|
|
endif()
|
|
endif()
|