mirror of
https://github.com/reactos/CMake.git
synced 2024-11-27 21:41:03 +00:00
c4275592a8
The FindPackageHandleStandardArgs module was originally created outside of CMake. It was added for CMake 2.6.0 by commite118a627(add a macro FIND_PACKAGE_HANDLE_STANDARD_ARGS..., 2007-07-18). However, it also proliferated into a number of other projects that at the time required only CMake 2.4 and thus could not depend on CMake to provide the module. CMake's own find modules started using the module in commitb5f656e0(use the new FIND_PACKAGE_HANDLE_STANDARD_ARGS in some of the FindXXX modules..., 2007-07-18). Then commitd358cf5c(add 2nd, more powerful mode to find_package_handle_standard_args, 2010-07-29) added a new feature to the interface of the module that was fully optional and backward compatible with all existing users of the module. Later commit5f183caa(FindZLIB: use the FPHSA version mode, 2010-08-04) and others shortly thereafter started using the new interface in CMake's own find modules. This change was also backward compatible because it was only an implementation detail within each module. Unforutnately these changes introduced a problem for projects that still have an old copy of FindPackageHandleStandardArgs in CMAKE_MODULE_PATH. When any such project uses one of CMake's builtin find modules the line include(FindPackageHandleStandardArgs) loads the copy from the project which does not have the new interface! Then the including find module tries to use the new interface with the old module and fails. Whether this breakage can be considered a backward incompatible change in CMake is debatable. The situation is analagous to copying a standard library header from one version of a compiler into a project and then observing problems when the next version of the compiler reports errors in its other headers that depend on its new version of the original header. Nevertheless it is a change to CMake that causes problems for projects that worked with previous versions. This problem was discovered during the 2.8.3 release candidate cycle. It is an instance of a more general problem with projects that provide their own versions of CMake modules when other CMake modules depend on them. At the time we resolved this instance of the problem with commitb0118402(Use absolute path to FindPackageHandleStandardArgs.cmake everywhere, 2010-09-28) for the 2.8.3 release. In order to address the more general problem we introduced policy CMP0017 in commitdb44848f(Prefer files from CMAKE_ROOT when including from CMAKE_ROOT, 2010-11-17). That change was followed by commitce28737c(Remove usage of CMAKE_CURRENT_LIST_DIR now that we have CMP0017, 2010-12-20) which reverted the original workaround in favor of using the policy. However, existing project releases do not set the policy behavior to NEW and therefore still exhibit the problem. We introduced in commita364daf1(Allow users to specify defaults for unset policies, 2011-01-03) an option for users to build existing projects by adding -DCMAKE_POLICY_DEFAULT_CMP0017=NEW to the command line. Unfortunately this solution still does not allow such projects to build out of the box, and there is no good way to suggest the use of the new option. The only remaining solution to keep existing projects that exhibit this problem building is to restore the change originally made in commitb0118402(Use absolute path to FindPackageHandleStandardArgs.cmake everywhere, 2010-09-28). This also avoids policy CMP0017 warnings for this particular instance of the problem the policy addresses.
140 lines
4.8 KiB
CMake
140 lines
4.8 KiB
CMake
# - This module looks for Doxygen and the path to Graphviz's dot
|
|
# Doxygen is a documentation generation tool. Please see
|
|
# http://www.doxygen.org
|
|
#
|
|
# This module accepts the following optional variables:
|
|
#
|
|
# DOXYGEN_SKIP_DOT = If true this module will skip trying to find Dot
|
|
# (an optional component often used by Doxygen)
|
|
#
|
|
# This modules defines the following variables:
|
|
#
|
|
# DOXYGEN_EXECUTABLE = The path to the doxygen command.
|
|
# DOXYGEN_FOUND = Was Doxygen found or not?
|
|
#
|
|
# DOXYGEN_DOT_EXECUTABLE = The path to the dot program used by doxygen.
|
|
# DOXYGEN_DOT_FOUND = Was Dot found or not?
|
|
# DOXYGEN_DOT_PATH = The path to dot not including the executable
|
|
#
|
|
#
|
|
|
|
#=============================================================================
|
|
# Copyright 2001-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
# For backwards compatibility support
|
|
IF(Doxygen_FIND_QUIETLY)
|
|
SET(DOXYGEN_FIND_QUIETLY TRUE)
|
|
ENDIF(Doxygen_FIND_QUIETLY)
|
|
|
|
# ===== Rationale for OS X AppBundle mods below =====
|
|
# With the OS X GUI version, Doxygen likes to be installed to /Applications and
|
|
# it contains the doxygen executable in the bundle. In the versions I've
|
|
# seen, it is located in Resources, but in general, more often binaries are
|
|
# located in MacOS.
|
|
#
|
|
# NOTE: The official Doxygen.app that is distributed for OS X uses non-standard
|
|
# conventions. Instead of the command-line "doxygen" tool being placed in
|
|
# Doxygen.app/Contents/MacOS, "Doxywizard" is placed there instead and
|
|
# "doxygen" is placed in Contents/Resources. This is most likely done
|
|
# so that something happens when people double-click on the Doxygen.app
|
|
# package. Unfortunately, CMake gets confused by this as when it sees the
|
|
# bundle it uses "Doxywizard" as the executable to use instead of
|
|
# "doxygen". Therefore to work-around this issue we temporarily disable
|
|
# the app-bundle feature, just for this CMake module:
|
|
if(APPLE)
|
|
# Save the old setting
|
|
SET(TEMP_DOXYGEN_SAVE_CMAKE_FIND_APPBUNDLE ${CMAKE_FIND_APPBUNDLE})
|
|
# Disable the App-bundle detection feature
|
|
SET(CMAKE_FIND_APPBUNDLE "NEVER")
|
|
endif()
|
|
# FYI:
|
|
# In the older versions of OS X Doxygen, dot was included with the
|
|
# Doxygen bundle. But the new versions require you to download
|
|
# Graphviz.app which contains "dot" in it's bundle.
|
|
# ============== End OSX stuff ================
|
|
|
|
#
|
|
# Find Doxygen...
|
|
#
|
|
|
|
FIND_PROGRAM(DOXYGEN_EXECUTABLE
|
|
NAMES doxygen
|
|
PATHS
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\doxygen_is1;Inno Setup: App Path]/bin"
|
|
/Applications/Doxygen.app/Contents/Resources
|
|
/Applications/Doxygen.app/Contents/MacOS
|
|
DOC "Doxygen documentation generation tool (http://www.doxygen.org)"
|
|
)
|
|
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
|
FIND_PACKAGE_HANDLE_STANDARD_ARGS(Doxygen DEFAULT_MSG DOXYGEN_EXECUTABLE)
|
|
|
|
#
|
|
# Find Dot...
|
|
#
|
|
|
|
IF(NOT DOXYGEN_SKIP_DOT)
|
|
FIND_PROGRAM(DOXYGEN_DOT_EXECUTABLE
|
|
NAMES dot
|
|
PATHS
|
|
"$ENV{ProgramFiles}/Graphviz 2.21/bin"
|
|
"C:/Program Files/Graphviz 2.21/bin"
|
|
"$ENV{ProgramFiles}/ATT/Graphviz/bin"
|
|
"C:/Program Files/ATT/Graphviz/bin"
|
|
[HKEY_LOCAL_MACHINE\\SOFTWARE\\ATT\\Graphviz;InstallPath]/bin
|
|
/Applications/Graphviz.app/Contents/MacOS
|
|
/Applications/Doxygen.app/Contents/Resources
|
|
/Applications/Doxygen.app/Contents/MacOS
|
|
DOC "Graphviz Dot tool for using Doxygen"
|
|
)
|
|
|
|
if(DOXYGEN_DOT_EXECUTABLE)
|
|
set(DOXYGEN_DOT_FOUND TRUE)
|
|
# The Doxyfile wants the path to Dot, not the entire path and executable
|
|
get_filename_component(DOXYGEN_DOT_PATH "${DOXYGEN_DOT_EXECUTABLE}" PATH CACHE)
|
|
endif()
|
|
|
|
endif(NOT DOXYGEN_SKIP_DOT)
|
|
|
|
#
|
|
# Backwards compatibility...
|
|
#
|
|
|
|
if(APPLE)
|
|
# Restore the old app-bundle setting setting
|
|
SET(CMAKE_FIND_APPBUNDLE ${TEMP_DOXYGEN_SAVE_CMAKE_FIND_APPBUNDLE})
|
|
endif()
|
|
|
|
# Maintain the _FOUND variables as "YES" or "NO" for backwards compatibility
|
|
# (allows people to stuff them directly into Doxyfile with configure_file())
|
|
if(DOXYGEN_FOUND)
|
|
set(DOXYGEN_FOUND "YES")
|
|
else()
|
|
set(DOXYGEN_FOUND "NO")
|
|
endif()
|
|
if(DOXYGEN_DOT_FOUND)
|
|
set(DOXYGEN_DOT_FOUND "YES")
|
|
else()
|
|
set(DOXYGEN_DOT_FOUND "NO")
|
|
endif()
|
|
|
|
# For backwards compatibility support
|
|
SET (DOXYGEN ${DOXYGEN_EXECUTABLE} )
|
|
SET (DOT ${DOXYGEN_DOT_EXECUTABLE} )
|
|
|
|
MARK_AS_ADVANCED(
|
|
DOXYGEN_EXECUTABLE
|
|
DOXYGEN_DOT_EXECUTABLE
|
|
DOXYGEN_DOT_PATH
|
|
)
|