mirror of
https://github.com/reactos/CMake.git
synced 2024-11-24 20:19:53 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
86 lines
3.1 KiB
CMake
86 lines
3.1 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# CheckLibraryExists
|
|
# ------------------
|
|
#
|
|
# Check if the function exists.
|
|
#
|
|
# CHECK_LIBRARY_EXISTS (LIBRARY FUNCTION LOCATION VARIABLE)
|
|
#
|
|
# ::
|
|
#
|
|
# LIBRARY - the name of the library you are looking for
|
|
# FUNCTION - the name of the function
|
|
# LOCATION - location where the library should be found
|
|
# VARIABLE - variable to store the result
|
|
# Will be created as an internal cache variable.
|
|
#
|
|
#
|
|
#
|
|
# The following variables may be set before calling this macro to modify
|
|
# the way the check is run:
|
|
#
|
|
# ::
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
|
# CMAKE_REQUIRED_QUIET = execute quietly without messages
|
|
|
|
macro(CHECK_LIBRARY_EXISTS LIBRARY FUNCTION LOCATION VARIABLE)
|
|
if(NOT DEFINED "${VARIABLE}")
|
|
set(MACRO_CHECK_LIBRARY_EXISTS_DEFINITION
|
|
"-DCHECK_FUNCTION_EXISTS=${FUNCTION} ${CMAKE_REQUIRED_FLAGS}")
|
|
if(NOT CMAKE_REQUIRED_QUIET)
|
|
message(STATUS "Looking for ${FUNCTION} in ${LIBRARY}")
|
|
endif()
|
|
set(CHECK_LIBRARY_EXISTS_LIBRARIES ${LIBRARY})
|
|
if(CMAKE_REQUIRED_LIBRARIES)
|
|
set(CHECK_LIBRARY_EXISTS_LIBRARIES
|
|
${CHECK_LIBRARY_EXISTS_LIBRARIES} ${CMAKE_REQUIRED_LIBRARIES})
|
|
endif()
|
|
|
|
if(CMAKE_C_COMPILER_LOADED)
|
|
set(_cle_source ${CMAKE_ROOT}/Modules/CheckFunctionExists.c)
|
|
elseif(CMAKE_CXX_COMPILER_LOADED)
|
|
set(_cle_source ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CheckLibraryExists/CheckFunctionExists.cxx)
|
|
configure_file(${CMAKE_ROOT}/Modules/CheckFunctionExists.c "${_cle_source}" COPYONLY)
|
|
else()
|
|
message(FATAL_ERROR "CHECK_FUNCTION_EXISTS needs either C or CXX language enabled")
|
|
endif()
|
|
|
|
try_compile(${VARIABLE}
|
|
${CMAKE_BINARY_DIR}
|
|
${_cle_source}
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
LINK_LIBRARIES ${CHECK_LIBRARY_EXISTS_LIBRARIES}
|
|
CMAKE_FLAGS
|
|
-DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_LIBRARY_EXISTS_DEFINITION}
|
|
-DLINK_DIRECTORIES:STRING=${LOCATION}
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
unset(_cle_source)
|
|
|
|
if(${VARIABLE})
|
|
if(NOT CMAKE_REQUIRED_QUIET)
|
|
message(STATUS "Looking for ${FUNCTION} in ${LIBRARY} - found")
|
|
endif()
|
|
set(${VARIABLE} 1 CACHE INTERNAL "Have library ${LIBRARY}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the function ${FUNCTION} exists in the ${LIBRARY} "
|
|
"passed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
else()
|
|
if(NOT CMAKE_REQUIRED_QUIET)
|
|
message(STATUS "Looking for ${FUNCTION} in ${LIBRARY} - not found")
|
|
endif()
|
|
set(${VARIABLE} "" CACHE INTERNAL "Have library ${LIBRARY}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the function ${FUNCTION} exists in the ${LIBRARY} "
|
|
"failed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
endif()
|
|
endif()
|
|
endmacro()
|