mirror of
https://github.com/reactos/CMake.git
synced 2024-11-23 11:39:48 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
58 lines
2.1 KiB
CMake
58 lines
2.1 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
|
|
# determine the compiler to use for RC programs
|
|
# NOTE, a generator may set CMAKE_RC_COMPILER before
|
|
# loading this file to force a compiler.
|
|
# use environment variable RC first if defined by user, next use
|
|
# the cmake variable CMAKE_GENERATOR_RC which can be defined by a generator
|
|
# as a default compiler
|
|
if(NOT CMAKE_RC_COMPILER)
|
|
# prefer the environment variable RC
|
|
if(NOT $ENV{RC} STREQUAL "")
|
|
get_filename_component(CMAKE_RC_COMPILER_INIT $ENV{RC} PROGRAM PROGRAM_ARGS CMAKE_RC_FLAGS_ENV_INIT)
|
|
if(CMAKE_RC_FLAGS_ENV_INIT)
|
|
set(CMAKE_RC_COMPILER_ARG1 "${CMAKE_RC_FLAGS_ENV_INIT}" CACHE STRING "First argument to RC compiler")
|
|
endif()
|
|
if(EXISTS ${CMAKE_RC_COMPILER_INIT})
|
|
else()
|
|
message(FATAL_ERROR "Could not find compiler set in environment variable RC:\n$ENV{RC}.")
|
|
endif()
|
|
endif()
|
|
|
|
# next try prefer the compiler specified by the generator
|
|
if(CMAKE_GENERATOR_RC)
|
|
if(NOT CMAKE_RC_COMPILER_INIT)
|
|
set(CMAKE_RC_COMPILER_INIT ${CMAKE_GENERATOR_RC})
|
|
endif()
|
|
endif()
|
|
|
|
# finally list compilers to try
|
|
if(CMAKE_RC_COMPILER_INIT)
|
|
set(CMAKE_RC_COMPILER_LIST ${CMAKE_RC_COMPILER_INIT})
|
|
else()
|
|
set(CMAKE_RC_COMPILER_LIST rc)
|
|
endif()
|
|
|
|
# Find the compiler.
|
|
find_program(CMAKE_RC_COMPILER NAMES ${CMAKE_RC_COMPILER_LIST} DOC "RC compiler")
|
|
if(CMAKE_RC_COMPILER_INIT AND NOT CMAKE_RC_COMPILER)
|
|
set(CMAKE_RC_COMPILER "${CMAKE_RC_COMPILER_INIT}" CACHE FILEPATH "RC compiler" FORCE)
|
|
endif()
|
|
endif()
|
|
|
|
mark_as_advanced(CMAKE_RC_COMPILER)
|
|
|
|
get_filename_component(_CMAKE_RC_COMPILER_NAME_WE ${CMAKE_RC_COMPILER} NAME_WE)
|
|
if(_CMAKE_RC_COMPILER_NAME_WE STREQUAL "windres")
|
|
set(CMAKE_RC_OUTPUT_EXTENSION .obj)
|
|
else()
|
|
set(CMAKE_RC_OUTPUT_EXTENSION .res)
|
|
endif()
|
|
|
|
# configure variables set in this file for fast reload later on
|
|
configure_file(${CMAKE_ROOT}/Modules/CMakeRCCompiler.cmake.in
|
|
${CMAKE_PLATFORM_INFO_DIR}/CMakeRCCompiler.cmake)
|
|
set(CMAKE_RC_COMPILER_ENV_VAR "RC")
|