mirror of
https://github.com/reactos/CMake.git
synced 2024-12-13 14:27:23 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
45 lines
1.4 KiB
Plaintext
45 lines
1.4 KiB
Plaintext
dnl Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
dnl file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
AC_DEFUN([CMAKE_FIND_BINARY],
|
|
[AC_ARG_VAR([CMAKE_BINARY], [path to the cmake binary])dnl
|
|
|
|
if test "x$ac_cv_env_CMAKE_BINARY_set" != "xset"; then
|
|
AC_PATH_TOOL([CMAKE_BINARY], [cmake])dnl
|
|
fi
|
|
])dnl
|
|
|
|
# $1: package name
|
|
# $2: language (e.g. C/CXX/Fortran)
|
|
# $3: The compiler ID, defaults to GNU.
|
|
# Possible values are: GNU, Intel, Clang, SunPro, HP, XL, VisualAge, PGI,
|
|
# PathScale, Cray, SCO, MIPSpro, MSVC
|
|
# $4: optional extra arguments to cmake, e.g. "-DCMAKE_SIZEOF_VOID_P=8"
|
|
# $5: optional path to cmake binary
|
|
AC_DEFUN([CMAKE_FIND_PACKAGE], [
|
|
AC_REQUIRE([CMAKE_FIND_BINARY])dnl
|
|
|
|
AC_ARG_VAR([$1][_][$2][FLAGS], [$2 compiler flags for $1. This overrides the cmake output])dnl
|
|
AC_ARG_VAR([$1][_LIBS], [linker flags for $1. This overrides the cmake output])dnl
|
|
|
|
failed=false
|
|
AC_MSG_CHECKING([for $1])
|
|
if test -n "$1[]_$2[]FLAGS"; then
|
|
$1[]_$2[]FLAGS=`$CMAKE_BINARY --find-package "-DNAME=$1" "-DCOMPILER_ID=m4_default([$3], [GNU])" "-DLANGUAGE=$2" -DMODE=COMPILE $4` || failed=true
|
|
fi
|
|
if test -n "$1[]_LIBS"; then
|
|
$1[]_LIBS=`$CMAKE_BINARY --find-package "-DNAME=$1" "-DCOMPILER_ID=m4_default([$3], [GNU])" "-DLANGUAGE=$2" -DMODE=LINK $4` || failed=true
|
|
fi
|
|
|
|
if $failed; then
|
|
unset $1[]_$2[]FLAGS
|
|
unset $1[]_LIBS
|
|
|
|
AC_MSG_RESULT([no])
|
|
$6
|
|
else
|
|
AC_MSG_RESULT([yes])
|
|
$5
|
|
fi[]dnl
|
|
])
|