mirror of
https://github.com/reactos/CMake.git
synced 2024-12-04 09:54:15 +00:00
c4bb9c9d42
This adds copyright/license notification blocks CMake's find-modules. Many of the modules had no notices at all. Some had notices referring to the BSD license already. This commit normalizes existing notices and adds missing notices.
62 lines
2.2 KiB
CMake
62 lines
2.2 KiB
CMake
# - Find the native PNG includes and library
|
|
#
|
|
# This module defines
|
|
# PNG_INCLUDE_DIR, where to find png.h, etc.
|
|
# PNG_LIBRARIES, the libraries to link against to use PNG.
|
|
# PNG_DEFINITIONS - You should add_definitons(${PNG_DEFINITIONS}) before compiling code that includes png library files.
|
|
# PNG_FOUND, If false, do not try to use PNG.
|
|
# also defined, but not for general use are
|
|
# PNG_LIBRARY, where to find the PNG library.
|
|
# None of the above will be defined unles zlib can be found.
|
|
# PNG depends on Zlib
|
|
|
|
#=============================================================================
|
|
# Copyright 2002-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distributed this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
if(PNG_FIND_QUIETLY)
|
|
set(_FIND_ZLIB_ARG QUIET)
|
|
endif(PNG_FIND_QUIETLY)
|
|
find_package(ZLIB ${_FIND_ZLIB_ARG})
|
|
|
|
if(ZLIB_FOUND)
|
|
find_path(PNG_PNG_INCLUDE_DIR png.h
|
|
/usr/local/include/libpng # OpenBSD
|
|
)
|
|
|
|
set(PNG_NAMES ${PNG_NAMES} png libpng png12 libpng12)
|
|
find_library(PNG_LIBRARY NAMES ${PNG_NAMES} )
|
|
|
|
if (PNG_LIBRARY AND PNG_PNG_INCLUDE_DIR)
|
|
# png.h includes zlib.h. Sigh.
|
|
SET(PNG_INCLUDE_DIR ${PNG_PNG_INCLUDE_DIR} ${ZLIB_INCLUDE_DIR} )
|
|
SET(PNG_LIBRARIES ${PNG_LIBRARY} ${ZLIB_LIBRARY})
|
|
|
|
if (CYGWIN)
|
|
if(BUILD_SHARED_LIBS)
|
|
# No need to define PNG_USE_DLL here, because it's default for Cygwin.
|
|
else(BUILD_SHARED_LIBS)
|
|
SET (PNG_DEFINITIONS -DPNG_STATIC)
|
|
endif(BUILD_SHARED_LIBS)
|
|
endif (CYGWIN)
|
|
|
|
endif (PNG_LIBRARY AND PNG_PNG_INCLUDE_DIR)
|
|
|
|
endif(ZLIB_FOUND)
|
|
|
|
# handle the QUIETLY and REQUIRED arguments and set PNG_FOUND to TRUE if
|
|
# all listed variables are TRUE
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(PNG DEFAULT_MSG PNG_LIBRARY PNG_PNG_INCLUDE_DIR)
|
|
|
|
mark_as_advanced(PNG_PNG_INCLUDE_DIR PNG_LIBRARY )
|