mirror of
https://github.com/reactos/CMake.git
synced 2025-01-11 22:17:44 +00:00
711b63f7e0
Historically CMake has always expanded ${} variable references in the
values given to include_directories(), link_directories(), and
link_libraries(). This has been unnecessary since general ${}
evaluation syntax was added to the language a LONG time ago, but has
remained for compatibility with VERY early CMake versions.
For a long time the re-expansion was a lightweight operation because it
was only processed once at the directory level and the fast-path of
cmMakefile::ExpandVariablesInString was usually taken because values did
not have any '$' in them. Then commit d899eb71 (Call
ExpandVariablesInString for each target's INCLUDE_DIRECTORIES,
2012-02-22) made the operation a bit heavier because the expansion is
now needed on a per-target basis. In the future we will support
generator expressions in INCLUDE_DIRECTORIES with $<> syntax, so the
fast-path in cmMakefile::ExpandVariablesInString will no longer be taken
and re-expansion will be very expensive.
Add policy CMP0019 to skip the re-expansion altogether in NEW behavior.
In OLD behavior perform the expansion but improve the fast-path
heuristic to match ${} but not $<>. If the policy is not set then warn
if expansion actually does anything. We expect this to be encountered
very rarely in practice.
65 lines
2.5 KiB
CMake
65 lines
2.5 KiB
CMake
# This directory contains tests that run CMake to configure a project
|
|
# but do not actually build anything. To add a test:
|
|
#
|
|
# 1.) Add a subdirectory named for the test.
|
|
#
|
|
# 2.) Call add_RunCMake_test and pass the test directory name.
|
|
#
|
|
# 3.) Create a RunCMakeTest.cmake script in the directory containing
|
|
# include(RunCMake)
|
|
# run_cmake(SubTest1)
|
|
# ...
|
|
# run_cmake(SubTestN)
|
|
# where SubTest1..SubTestN are sub-test names each corresponding to
|
|
# an independent CMake run and project configuration.
|
|
#
|
|
# 3.) Create a CMakeLists.txt file in the directory containing
|
|
# cmake_minimum_required(...)
|
|
# project(${RunCMake_TEST} NONE) # or languages needed
|
|
# include(${RunCMake_TEST}.cmake)
|
|
# where "${RunCMake_TEST}" is literal. A value for RunCMake_TEST
|
|
# will be passed to CMake by the run_cmake macro when running each
|
|
# sub-test.
|
|
#
|
|
# 4.) Create a <SubTest>.cmake file for each sub-test named above
|
|
# containing the actual test code. Optionally create files
|
|
# containing expected test results:
|
|
# <SubTest>-result.txt = Process result expected if not "0"
|
|
# <SubTest>-stdout.txt = Regex matching expected stdout content
|
|
# <SubTest>-stderr.txt = Regex matching expected stderr content
|
|
# <SubTest>-check.cmake = Custom result check
|
|
# Note that trailing newlines will be stripped from actual test
|
|
# output before matching against the stdout and stderr expressions.
|
|
# The code in <SubTest>-check.cmake may use variables
|
|
# RunCMake_TEST_SOURCE_DIR = Top of test source tree
|
|
# RunCMake_TEST_BINARY_DIR = Top of test binary tree
|
|
# and an failure must store a message in RunCMake_TEST_FAILED.
|
|
|
|
macro(add_RunCMake_test test)
|
|
add_test(RunCMake.${test} ${CMAKE_CMAKE_COMMAND}
|
|
-DCMAKE_MODULE_PATH=${CMAKE_CURRENT_SOURCE_DIR}
|
|
-DRunCMake_GENERATOR=${CMAKE_TEST_GENERATOR}
|
|
-DRunCMake_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}/${test}
|
|
-DRunCMake_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}/${test}
|
|
-P "${CMAKE_CURRENT_SOURCE_DIR}/${test}/RunCMakeTest.cmake"
|
|
)
|
|
endmacro()
|
|
|
|
add_RunCMake_test(CMP0019)
|
|
add_RunCMake_test(GeneratorExpression)
|
|
add_RunCMake_test(TargetPropertyGeneratorExpressions)
|
|
add_RunCMake_test(Languages)
|
|
add_RunCMake_test(ObjectLibrary)
|
|
|
|
add_RunCMake_test(build_command)
|
|
add_RunCMake_test(find_package)
|
|
add_RunCMake_test(include)
|
|
add_RunCMake_test(include_directories)
|
|
add_RunCMake_test(list)
|
|
add_RunCMake_test(load_command)
|
|
|
|
if("${CMAKE_TEST_GENERATOR}" MATCHES "Visual Studio [^6]")
|
|
add_RunCMake_test(include_external_msproject)
|
|
add_RunCMake_test(SolutionGlobalSections)
|
|
endif()
|