mirror of
https://github.com/reactos/CMake.git
synced 2024-11-23 11:39:48 +00:00
73d28d2177
Previously if headers required to check if a struct has a member can be
compiled with C++ compiler only, the check would fail because the C
compiler fails. As a consequence, the result variable would be set to
false, even if the struct has that particular member.
Teach CHECK_STRUCT_HAS_MEMBER to accept a new optional argument LANGUAGE
that allows one to explicitly set the compiler to use. The new
signature is therefore:
CHECK_STRUCT_HAS_MEMBER (<struct> <member> <header> <variable>
[LANGUAGE <language>])
69 lines
2.5 KiB
CMake
69 lines
2.5 KiB
CMake
# - Check if the given struct or class has the specified member variable
|
|
# CHECK_STRUCT_HAS_MEMBER (<struct> <member> <header> <variable>
|
|
# [LANGUAGE <language>])
|
|
#
|
|
# <struct> - the name of the struct or class you are interested in
|
|
# <member> - the member which existence you want to check
|
|
# <header> - the header(s) where the prototype should be declared
|
|
# <variable> - variable to store the result
|
|
# <language> - the compiler to use (C or CXX)
|
|
#
|
|
# The following variables may be set before calling this macro to
|
|
# modify the way the check is run:
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_INCLUDES = list of include directories
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
|
#
|
|
# Example: CHECK_STRUCT_HAS_MEMBER("struct timeval" tv_sec sys/select.h HAVE_TIMEVAL_TV_SEC LANGUAGE C)
|
|
|
|
#=============================================================================
|
|
# Copyright 2007-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
include(CheckCSourceCompiles)
|
|
include(CheckCXXSourceCompiles)
|
|
|
|
macro (CHECK_STRUCT_HAS_MEMBER _STRUCT _MEMBER _HEADER _RESULT)
|
|
set(_INCLUDE_FILES)
|
|
foreach (it ${_HEADER})
|
|
set(_INCLUDE_FILES "${_INCLUDE_FILES}#include <${it}>\n")
|
|
endforeach ()
|
|
|
|
if("x${ARGN}" STREQUAL "x")
|
|
set(_lang C)
|
|
elseif("x${ARGN}" MATCHES "^xLANGUAGE;([a-zA-Z]+)$")
|
|
set(_lang "${CMAKE_MATCH_1}")
|
|
else()
|
|
message(FATAL_ERROR "Unknown arguments:\n ${ARGN}\n")
|
|
endif()
|
|
|
|
set(_CHECK_STRUCT_MEMBER_SOURCE_CODE "
|
|
${_INCLUDE_FILES}
|
|
int main()
|
|
{
|
|
${_STRUCT}* tmp;
|
|
tmp->${_MEMBER};
|
|
return 0;
|
|
}
|
|
")
|
|
|
|
if("${_lang}" STREQUAL "C")
|
|
CHECK_C_SOURCE_COMPILES("${_CHECK_STRUCT_MEMBER_SOURCE_CODE}" ${_RESULT})
|
|
elseif("${_lang}" STREQUAL "CXX")
|
|
CHECK_CXX_SOURCE_COMPILES("${_CHECK_STRUCT_MEMBER_SOURCE_CODE}" ${_RESULT})
|
|
else()
|
|
message(FATAL_ERROR "Unknown language:\n ${_lang}\nSupported languages: C, CXX.\n")
|
|
endif()
|
|
endmacro ()
|