mirror of
https://github.com/reactos/CMake.git
synced 2024-11-29 14:30:27 +00:00
c4275592a8
The FindPackageHandleStandardArgs module was originally created outside of CMake. It was added for CMake 2.6.0 by commite118a627(add a macro FIND_PACKAGE_HANDLE_STANDARD_ARGS..., 2007-07-18). However, it also proliferated into a number of other projects that at the time required only CMake 2.4 and thus could not depend on CMake to provide the module. CMake's own find modules started using the module in commitb5f656e0(use the new FIND_PACKAGE_HANDLE_STANDARD_ARGS in some of the FindXXX modules..., 2007-07-18). Then commitd358cf5c(add 2nd, more powerful mode to find_package_handle_standard_args, 2010-07-29) added a new feature to the interface of the module that was fully optional and backward compatible with all existing users of the module. Later commit5f183caa(FindZLIB: use the FPHSA version mode, 2010-08-04) and others shortly thereafter started using the new interface in CMake's own find modules. This change was also backward compatible because it was only an implementation detail within each module. Unforutnately these changes introduced a problem for projects that still have an old copy of FindPackageHandleStandardArgs in CMAKE_MODULE_PATH. When any such project uses one of CMake's builtin find modules the line include(FindPackageHandleStandardArgs) loads the copy from the project which does not have the new interface! Then the including find module tries to use the new interface with the old module and fails. Whether this breakage can be considered a backward incompatible change in CMake is debatable. The situation is analagous to copying a standard library header from one version of a compiler into a project and then observing problems when the next version of the compiler reports errors in its other headers that depend on its new version of the original header. Nevertheless it is a change to CMake that causes problems for projects that worked with previous versions. This problem was discovered during the 2.8.3 release candidate cycle. It is an instance of a more general problem with projects that provide their own versions of CMake modules when other CMake modules depend on them. At the time we resolved this instance of the problem with commitb0118402(Use absolute path to FindPackageHandleStandardArgs.cmake everywhere, 2010-09-28) for the 2.8.3 release. In order to address the more general problem we introduced policy CMP0017 in commitdb44848f(Prefer files from CMAKE_ROOT when including from CMAKE_ROOT, 2010-11-17). That change was followed by commitce28737c(Remove usage of CMAKE_CURRENT_LIST_DIR now that we have CMP0017, 2010-12-20) which reverted the original workaround in favor of using the policy. However, existing project releases do not set the policy behavior to NEW and therefore still exhibit the problem. We introduced in commita364daf1(Allow users to specify defaults for unset policies, 2011-01-03) an option for users to build existing projects by adding -DCMAKE_POLICY_DEFAULT_CMP0017=NEW to the command line. Unfortunately this solution still does not allow such projects to build out of the box, and there is no good way to suggest the use of the new option. The only remaining solution to keep existing projects that exhibit this problem building is to restore the change originally made in commitb0118402(Use absolute path to FindPackageHandleStandardArgs.cmake everywhere, 2010-09-28). This also avoids policy CMP0017 warnings for this particular instance of the problem the policy addresses.
115 lines
3.6 KiB
CMake
115 lines
3.6 KiB
CMake
# - Finds OpenMP support
|
|
# This module can be used to detect OpenMP support in a compiler.
|
|
# If the compiler supports OpenMP, the flags required to compile with
|
|
# openmp support are set.
|
|
#
|
|
# The following variables are set:
|
|
# OpenMP_C_FLAGS - flags to add to the C compiler for OpenMP support
|
|
# OpenMP_CXX_FLAGS - flags to add to the CXX compiler for OpenMP support
|
|
# OPENMP_FOUND - true if openmp is detected
|
|
#
|
|
# Supported compilers can be found at http://openmp.org/wp/openmp-compilers/
|
|
|
|
#=============================================================================
|
|
# Copyright 2009 Kitware, Inc.
|
|
# Copyright 2008-2009 André Rigland Brodtkorb <Andre.Brodtkorb@ifi.uio.no>
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
include(CheckCSourceCompiles)
|
|
include(CheckCXXSourceCompiles)
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
|
|
|
set(OpenMP_C_FLAG_CANDIDATES
|
|
#Gnu
|
|
"-fopenmp"
|
|
#Microsoft Visual Studio
|
|
"/openmp"
|
|
#Intel windows
|
|
"-Qopenmp"
|
|
#Intel
|
|
"-openmp"
|
|
#Empty, if compiler automatically accepts openmp
|
|
" "
|
|
#Sun
|
|
"-xopenmp"
|
|
#HP
|
|
"+Oopenmp"
|
|
#IBM XL C/c++
|
|
"-qsmp"
|
|
#Portland Group
|
|
"-mp"
|
|
)
|
|
set(OpenMP_CXX_FLAG_CANDIDATES ${OpenMP_C_FLAG_CANDIDATES})
|
|
|
|
# sample openmp source code to test
|
|
set(OpenMP_C_TEST_SOURCE
|
|
"
|
|
#include <omp.h>
|
|
int main() {
|
|
#ifdef _OPENMP
|
|
return 0;
|
|
#else
|
|
breaks_on_purpose
|
|
#endif
|
|
}
|
|
")
|
|
# use the same source for CXX as C for now
|
|
set(OpenMP_CXX_TEST_SOURCE ${OpenMP_C_TEST_SOURCE})
|
|
# if these are set then do not try to find them again,
|
|
# by avoiding any try_compiles for the flags
|
|
if(DEFINED OpenMP_C_FLAGS AND DEFINED OpenMP_CXX_FLAGS)
|
|
set(OpenMP_C_FLAG_CANDIDATES)
|
|
set(OpenMP_CXX_FLAG_CANDIDATES)
|
|
endif(DEFINED OpenMP_C_FLAGS AND DEFINED OpenMP_CXX_FLAGS)
|
|
|
|
# check c compiler
|
|
foreach(FLAG ${OpenMP_C_FLAG_CANDIDATES})
|
|
set(SAFE_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
|
|
set(CMAKE_REQUIRED_FLAGS "${FLAG}")
|
|
unset(OpenMP_FLAG_DETECTED CACHE)
|
|
message(STATUS "Try OpenMP C flag = [${FLAG}]")
|
|
check_c_source_compiles("${OpenMP_CXX_TEST_SOURCE}" OpenMP_FLAG_DETECTED)
|
|
set(CMAKE_REQUIRED_FLAGS "${SAFE_CMAKE_REQUIRED_FLAGS}")
|
|
if(OpenMP_FLAG_DETECTED)
|
|
set(OpenMP_C_FLAGS_INTERNAL "${FLAG}")
|
|
break()
|
|
endif(OpenMP_FLAG_DETECTED)
|
|
endforeach(FLAG ${OpenMP_C_FLAG_CANDIDATES})
|
|
|
|
# check cxx compiler
|
|
foreach(FLAG ${OpenMP_CXX_FLAG_CANDIDATES})
|
|
set(SAFE_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
|
|
set(CMAKE_REQUIRED_FLAGS "${FLAG}")
|
|
unset(OpenMP_FLAG_DETECTED CACHE)
|
|
message(STATUS "Try OpenMP CXX flag = [${FLAG}]")
|
|
check_cxx_source_compiles("${OpenMP_C_TEST_SOURCE}" OpenMP_FLAG_DETECTED)
|
|
set(CMAKE_REQUIRED_FLAGS "${SAFE_CMAKE_REQUIRED_FLAGS}")
|
|
if(OpenMP_FLAG_DETECTED)
|
|
set(OpenMP_CXX_FLAGS_INTERNAL "${FLAG}")
|
|
break()
|
|
endif(OpenMP_FLAG_DETECTED)
|
|
endforeach(FLAG ${OpenMP_CXX_FLAG_CANDIDATES})
|
|
|
|
set(OpenMP_C_FLAGS "${OpenMP_C_FLAGS_INTERNAL}"
|
|
CACHE STRING "C compiler flags for OpenMP parallization")
|
|
|
|
set(OpenMP_CXX_FLAGS "${OpenMP_CXX_FLAGS_INTERNAL}"
|
|
CACHE STRING "C++ compiler flags for OpenMP parallization")
|
|
# handle the standard arguments for find_package
|
|
find_package_handle_standard_args(OpenMP DEFAULT_MSG
|
|
OpenMP_C_FLAGS OpenMP_CXX_FLAGS )
|
|
|
|
mark_as_advanced(
|
|
OpenMP_C_FLAGS
|
|
OpenMP_CXX_FLAGS
|
|
)
|