mirror of
https://github.com/reactos/CMake.git
synced 2024-11-29 14:30:27 +00:00
236133e79e
Imported targets are re-exported so that they can be used by the try_compile generated code with target_link_libraries. This makes the use of the cmake_expand_imported_targets macro obsolete. The macro is not able to expand the generator expressions which may appear in the IMPORTED_LINK_INTERFACE_LIBRARIES content. Instead it just sees them as 'not a target'.
72 lines
3.0 KiB
CMake
72 lines
3.0 KiB
CMake
# - Check if a C function can be linked
|
|
# CHECK_FUNCTION_EXISTS(<function> <variable>)
|
|
#
|
|
# Check that the <function> is provided by libraries on the system and
|
|
# store the result in a <variable>. This does not verify that any
|
|
# system header file declares the function, only that it can be found
|
|
# at link time (considure using CheckSymbolExists).
|
|
#
|
|
# The following variables may be set before calling this macro to
|
|
# modify the way the check is run:
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_INCLUDES = list of include directories
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
|
|
|
#=============================================================================
|
|
# Copyright 2002-2011 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
|
|
|
|
macro(CHECK_FUNCTION_EXISTS FUNCTION VARIABLE)
|
|
if("${VARIABLE}" MATCHES "^${VARIABLE}$")
|
|
set(MACRO_CHECK_FUNCTION_DEFINITIONS
|
|
"-DCHECK_FUNCTION_EXISTS=${FUNCTION} ${CMAKE_REQUIRED_FLAGS}")
|
|
message(STATUS "Looking for ${FUNCTION}")
|
|
if(CMAKE_REQUIRED_LIBRARIES)
|
|
set(CHECK_FUNCTION_EXISTS_ADD_LIBRARIES
|
|
LINK_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
|
|
else()
|
|
set(CHECK_FUNCTION_EXISTS_ADD_LIBRARIES)
|
|
endif()
|
|
if(CMAKE_REQUIRED_INCLUDES)
|
|
set(CHECK_FUNCTION_EXISTS_ADD_INCLUDES
|
|
"-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}")
|
|
else()
|
|
set(CHECK_FUNCTION_EXISTS_ADD_INCLUDES)
|
|
endif()
|
|
try_compile(${VARIABLE}
|
|
${CMAKE_BINARY_DIR}
|
|
${CMAKE_ROOT}/Modules/CheckFunctionExists.c
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
${CHECK_FUNCTION_EXISTS_ADD_LIBRARIES}
|
|
CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS}
|
|
"${CHECK_FUNCTION_EXISTS_ADD_INCLUDES}"
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
if(${VARIABLE})
|
|
set(${VARIABLE} 1 CACHE INTERNAL "Have function ${FUNCTION}")
|
|
message(STATUS "Looking for ${FUNCTION} - found")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the function ${FUNCTION} exists passed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
else()
|
|
message(STATUS "Looking for ${FUNCTION} - not found")
|
|
set(${VARIABLE} "" CACHE INTERNAL "Have function ${FUNCTION}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the function ${FUNCTION} exists failed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
endif()
|
|
endif()
|
|
endmacro()
|