mirror of
https://github.com/reactos/CMake.git
synced 2024-11-25 04:29:52 +00:00
f051814ed0
Run the convert-help.bash script to convert documentation: ./convert-help.bash "/path/to/CMake-build/bin" Then remove it.
88 lines
3.1 KiB
CMake
88 lines
3.1 KiB
CMake
#.rst:
|
|
# CheckIncludeFile
|
|
# ----------------
|
|
#
|
|
# macro which checks the include file exists.
|
|
#
|
|
# CHECK_INCLUDE_FILE(INCLUDE VARIABLE)
|
|
#
|
|
# ::
|
|
#
|
|
# INCLUDE - name of include file
|
|
# VARIABLE - variable to return result
|
|
#
|
|
#
|
|
#
|
|
# an optional third argument is the CFlags to add to the compile line or
|
|
# you can use CMAKE_REQUIRED_FLAGS
|
|
#
|
|
# The following variables may be set before calling this macro to modify
|
|
# the way the check is run:
|
|
#
|
|
# ::
|
|
#
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
|
# CMAKE_REQUIRED_INCLUDES = list of include directories
|
|
|
|
#=============================================================================
|
|
# Copyright 2002-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
macro(CHECK_INCLUDE_FILE INCLUDE VARIABLE)
|
|
if("${VARIABLE}" MATCHES "^${VARIABLE}$")
|
|
if(CMAKE_REQUIRED_INCLUDES)
|
|
set(CHECK_INCLUDE_FILE_C_INCLUDE_DIRS "-DINCLUDE_DIRECTORIES=${CMAKE_REQUIRED_INCLUDES}")
|
|
else()
|
|
set(CHECK_INCLUDE_FILE_C_INCLUDE_DIRS)
|
|
endif()
|
|
set(MACRO_CHECK_INCLUDE_FILE_FLAGS ${CMAKE_REQUIRED_FLAGS})
|
|
set(CHECK_INCLUDE_FILE_VAR ${INCLUDE})
|
|
configure_file(${CMAKE_ROOT}/Modules/CheckIncludeFile.c.in
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/CheckIncludeFile.c IMMEDIATE)
|
|
message(STATUS "Looking for ${INCLUDE}")
|
|
if(${ARGC} EQUAL 3)
|
|
set(CMAKE_C_FLAGS_SAVE ${CMAKE_C_FLAGS})
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${ARGV2}")
|
|
endif()
|
|
|
|
try_compile(${VARIABLE}
|
|
${CMAKE_BINARY_DIR}
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/CheckIncludeFile.c
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
|
CMAKE_FLAGS
|
|
-DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_INCLUDE_FILE_FLAGS}
|
|
"${CHECK_INCLUDE_FILE_C_INCLUDE_DIRS}"
|
|
OUTPUT_VARIABLE OUTPUT)
|
|
|
|
if(${ARGC} EQUAL 3)
|
|
set(CMAKE_C_FLAGS ${CMAKE_C_FLAGS_SAVE})
|
|
endif()
|
|
|
|
if(${VARIABLE})
|
|
message(STATUS "Looking for ${INCLUDE} - found")
|
|
set(${VARIABLE} 1 CACHE INTERNAL "Have include ${INCLUDE}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
|
"Determining if the include file ${INCLUDE} "
|
|
"exists passed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
else()
|
|
message(STATUS "Looking for ${INCLUDE} - not found")
|
|
set(${VARIABLE} "" CACHE INTERNAL "Have include ${INCLUDE}")
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
|
"Determining if the include file ${INCLUDE} "
|
|
"exists failed with the following output:\n"
|
|
"${OUTPUT}\n\n")
|
|
endif()
|
|
endif()
|
|
endmacro()
|