mirror of
https://github.com/reactos/CMake.git
synced 2025-02-08 04:48:46 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
55 lines
1.7 KiB
CMake
55 lines
1.7 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# FindALSA
|
|
# --------
|
|
#
|
|
# Find alsa
|
|
#
|
|
# Find the alsa libraries (asound)
|
|
#
|
|
# ::
|
|
#
|
|
# This module defines the following variables:
|
|
# ALSA_FOUND - True if ALSA_INCLUDE_DIR & ALSA_LIBRARY are found
|
|
# ALSA_LIBRARIES - Set when ALSA_LIBRARY is found
|
|
# ALSA_INCLUDE_DIRS - Set when ALSA_INCLUDE_DIR is found
|
|
#
|
|
#
|
|
#
|
|
# ::
|
|
#
|
|
# ALSA_INCLUDE_DIR - where to find asoundlib.h, etc.
|
|
# ALSA_LIBRARY - the asound library
|
|
# ALSA_VERSION_STRING - the version of alsa found (since CMake 2.8.8)
|
|
|
|
find_path(ALSA_INCLUDE_DIR NAMES alsa/asoundlib.h
|
|
DOC "The ALSA (asound) include directory"
|
|
)
|
|
|
|
find_library(ALSA_LIBRARY NAMES asound
|
|
DOC "The ALSA (asound) library"
|
|
)
|
|
|
|
if(ALSA_INCLUDE_DIR AND EXISTS "${ALSA_INCLUDE_DIR}/alsa/version.h")
|
|
file(STRINGS "${ALSA_INCLUDE_DIR}/alsa/version.h" alsa_version_str REGEX "^#define[\t ]+SND_LIB_VERSION_STR[\t ]+\".*\"")
|
|
|
|
string(REGEX REPLACE "^.*SND_LIB_VERSION_STR[\t ]+\"([^\"]*)\".*$" "\\1" ALSA_VERSION_STRING "${alsa_version_str}")
|
|
unset(alsa_version_str)
|
|
endif()
|
|
|
|
# handle the QUIETLY and REQUIRED arguments and set ALSA_FOUND to TRUE if
|
|
# all listed variables are TRUE
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
|
FIND_PACKAGE_HANDLE_STANDARD_ARGS(ALSA
|
|
REQUIRED_VARS ALSA_LIBRARY ALSA_INCLUDE_DIR
|
|
VERSION_VAR ALSA_VERSION_STRING)
|
|
|
|
if(ALSA_FOUND)
|
|
set( ALSA_LIBRARIES ${ALSA_LIBRARY} )
|
|
set( ALSA_INCLUDE_DIRS ${ALSA_INCLUDE_DIR} )
|
|
endif()
|
|
|
|
mark_as_advanced(ALSA_INCLUDE_DIR ALSA_LIBRARY)
|