mirror of
https://github.com/reactos/CMake.git
synced 2024-11-25 12:40:06 +00:00
86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
48 lines
1.5 KiB
CMake
48 lines
1.5 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#.rst:
|
|
# FindPackageMessage
|
|
# ------------------
|
|
#
|
|
#
|
|
#
|
|
# FIND_PACKAGE_MESSAGE(<name> "message for user" "find result details")
|
|
#
|
|
# This macro is intended to be used in FindXXX.cmake modules files. It
|
|
# will print a message once for each unique find result. This is useful
|
|
# for telling the user where a package was found. The first argument
|
|
# specifies the name (XXX) of the package. The second argument
|
|
# specifies the message to display. The third argument lists details
|
|
# about the find result so that if they change the message will be
|
|
# displayed again. The macro also obeys the QUIET argument to the
|
|
# find_package command.
|
|
#
|
|
# Example:
|
|
#
|
|
# ::
|
|
#
|
|
# if(X11_FOUND)
|
|
# FIND_PACKAGE_MESSAGE(X11 "Found X11: ${X11_X11_LIB}"
|
|
# "[${X11_X11_LIB}][${X11_INCLUDE_DIR}]")
|
|
# else()
|
|
# ...
|
|
# endif()
|
|
|
|
function(FIND_PACKAGE_MESSAGE pkg msg details)
|
|
# Avoid printing a message repeatedly for the same find result.
|
|
if(NOT ${pkg}_FIND_QUIETLY)
|
|
string(REPLACE "\n" "" details "${details}")
|
|
set(DETAILS_VAR FIND_PACKAGE_MESSAGE_DETAILS_${pkg})
|
|
if(NOT "${details}" STREQUAL "${${DETAILS_VAR}}")
|
|
# The message has not yet been printed.
|
|
message(STATUS "${msg}")
|
|
|
|
# Save the find details in the cache to avoid printing the same
|
|
# message again.
|
|
set("${DETAILS_VAR}" "${details}"
|
|
CACHE INTERNAL "Details about finding ${pkg}")
|
|
endif()
|
|
endif()
|
|
endfunction()
|