mirror of
https://github.com/joel16/uofw.git
synced 2025-02-22 03:40:36 +00:00
484569d7fb
Fixed alignment. Added our/my own version of psp-build-exports from the PSPSDK, so the library name is placed right before the library exports in .rodata. Added our/my own version of psp-prxgen from the PSPSDK (named psp-kprxgen for us), so the module uses only program headers and absolutely no sections.
245 lines
9.6 KiB
Plaintext
245 lines
9.6 KiB
Plaintext
/* Default linker script, for normal executables */
|
|
OUTPUT_FORMAT("elf32-littlemips", "elf32-bigmips",
|
|
"elf32-littlemips")
|
|
OUTPUT_ARCH(mips:allegrex)
|
|
ENTRY(module_start)
|
|
/* SEARCH_DIR("/usr/local/pspdev/psp/lib"); */
|
|
/* Do we need any of these for elf?
|
|
__DYNAMIC = 0; */
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
PROVIDE (__executable_start = 0x0); . = 0x0;
|
|
.interp : { *(.interp) }
|
|
.dynamic : { *(.dynamic) }
|
|
.hash : { *(.hash) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.gnu.version : { *(.gnu.version) }
|
|
.gnu.version_d : { *(.gnu.version_d) }
|
|
.gnu.version_r : { *(.gnu.version_r) }
|
|
.rel.text : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
|
|
.rela.text : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
|
|
.rel.init : { *(.rel.init) }
|
|
.rela.init : { *(.rela.init) }
|
|
.rel.fini : { *(.rel.fini) }
|
|
.rela.fini : { *(.rela.fini) }
|
|
/* PSP-specific relocations. */
|
|
.rel.sceStub.text : { *(.rel.sceStub.text) *(SORT(.rel.sceStub.text.*)) }
|
|
.rel.lib.ent.top : { *(.rel.lib.ent.top) }
|
|
.rel.lib.ent : { *(.rel.lib.ent) }
|
|
.rel.lib.ent.btm : { *(.rel.lib.ent.btm) }
|
|
.rel.lib.stub.top : { *(.rel.lib.stub.top) }
|
|
.rel.lib.stub : { *(.rel.lib.stub) }
|
|
.rel.lib.stub.btm : { *(.rel.lib.stub.btm) }
|
|
.rel.rodata.sceModuleInfo : { *(.rel.rodata.sceModuleInfo) }
|
|
.rel.rodata.sceResident : { *(.rel.rodata.sceResident) }
|
|
.rel.rodata.sceNid : { *(.rel.rodata.sceNid) }
|
|
.rel.rodata.sceVstub : { *(.rel.rodata.sceVstub) *(SORT(.rel.rodata.sceVstub.*)) }
|
|
.rel.rodata : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
|
|
.rela.rodata : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
|
|
.rel.data.rel.ro : { *(.rel.data.rel.ro*) }
|
|
.rela.data.rel.ro : { *(.rel.data.rel.ro*) }
|
|
.rel.data : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
|
|
.rela.data : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
|
|
.rel.tdata : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
|
|
.rela.tdata : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
|
|
.rel.tbss : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
|
|
.rela.tbss : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
|
|
.rel.ctors : { *(.rel.ctors) }
|
|
.rela.ctors : { *(.rela.ctors) }
|
|
.rel.dtors : { *(.rel.dtors) }
|
|
.rela.dtors : { *(.rela.dtors) }
|
|
.rel.got : { *(.rel.got) }
|
|
.rela.got : { *(.rela.got) }
|
|
.rel.sdata : { *(.rel.sdata .rel.sdata.* .rel.gnu.linkonce.s.*) }
|
|
.rela.sdata : { *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*) }
|
|
.rel.sbss : { *(.rel.sbss .rel.sbss.* .rel.gnu.linkonce.sb.*) }
|
|
.rela.sbss : { *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*) }
|
|
.rel.sdata2 : { *(.rel.sdata2 .rel.sdata2.* .rel.gnu.linkonce.s2.*) }
|
|
.rela.sdata2 : { *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*) }
|
|
.rel.sbss2 : { *(.rel.sbss2 .rel.sbss2.* .rel.gnu.linkonce.sb2.*) }
|
|
.rela.sbss2 : { *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*) }
|
|
.rel.bss : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
|
|
.rela.bss : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
|
|
.rel.plt : { *(.rel.plt) }
|
|
.rela.plt : { *(.rela.plt) }
|
|
.text :
|
|
{
|
|
_ftext = . ;
|
|
*(.text .stub .text.* .gnu.linkonce.t.*)
|
|
KEEP (*(.text.*personality*))
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
*(.mips16.fn.*) *(.mips16.call.*)
|
|
} =0
|
|
. = ALIGN(16);
|
|
.init :
|
|
{
|
|
KEEP (*(.init))
|
|
} =0
|
|
.plt : { *(.plt) }
|
|
.fini :
|
|
{
|
|
KEEP (*(.fini))
|
|
} =0
|
|
/* PSP library stub functions. */
|
|
.sceStub.text : { *(.sceStub.text) *(SORT(.sceStub.text.*)) }
|
|
PROVIDE (__etext = .);
|
|
PROVIDE (_etext = .);
|
|
PROVIDE (etext = .);
|
|
/* PSP library entry table and library stub table. */
|
|
.lib.ent.top : { *(.lib.ent.top) }
|
|
.lib.ent : { *(.lib.ent) }
|
|
.lib.ent.btm : { *(.lib.ent.btm) }
|
|
.lib.stub.top : { *(.lib.stub.top) }
|
|
.lib.stub : { *(.lib.stub) }
|
|
.lib.stub.btm : { *(.lib.stub.btm) }
|
|
/* PSP read-only data for module info, NIDs, and Vstubs. The
|
|
.rodata.sceModuleInfo section must appear before the .rodata section
|
|
otherwise it would get absorbed into .rodata and the PSP bootloader
|
|
would be unable to locate the module info structure. */
|
|
.rodata.sceModuleInfo : { *(.rodata.sceModuleInfo) }
|
|
.rodata.sceResident : { *(.rodata.sceResident) }
|
|
.rodata.sceNid : { KEEP (*(.rodata.sceNid)) }
|
|
.rodata.sceVstub : { *(.rodata.sceVstub) *(SORT(.rodata.sceVstub.*)) }
|
|
.rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
|
|
.rodata1 : { *(.rodata1) }
|
|
.sdata2 : { *(.sdata2 .sdata2.* .gnu.linkonce.s2.*) }
|
|
.sbss2 : { *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*) }
|
|
.eh_frame_hdr : { *(.eh_frame_hdr) }
|
|
.eh_frame : ONLY_IF_RO { KEEP (*(.eh_frame)) }
|
|
.gcc_except_table : ONLY_IF_RO { KEEP (*(.gcc_except_table)) *(.gcc_except_table.*) }
|
|
/* Exception handling */
|
|
.eh_frame : ONLY_IF_RW { KEEP (*(.eh_frame)) }
|
|
.gcc_except_table : ONLY_IF_RW { KEEP (*(.gcc_except_table)) *(.gcc_except_table.*) }
|
|
/* Thread Local Storage sections */
|
|
.tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
|
|
.tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
|
|
/* Ensure the __preinit_array_start label is properly aligned. We
|
|
could instead move the label definition inside the section, but
|
|
the linker would then create the section even if it turns out to
|
|
be empty, which isn't pretty. */
|
|
. = ALIGN(32 / 8);
|
|
PROVIDE (__preinit_array_start = .);
|
|
.preinit_array : { KEEP (*(.preinit_array)) }
|
|
PROVIDE (__preinit_array_end = .);
|
|
PROVIDE (__init_array_start = .);
|
|
.init_array : { KEEP (*(.init_array)) }
|
|
PROVIDE (__init_array_end = .);
|
|
PROVIDE (__fini_array_start = .);
|
|
.fini_array : { KEEP (*(.fini_array)) }
|
|
PROVIDE (__fini_array_end = .);
|
|
.ctors :
|
|
{
|
|
/* gcc uses crtbegin.o to find the start of
|
|
the constructors, so we make sure it is
|
|
first. Because this is a wildcard, it
|
|
doesn't matter if the user does not
|
|
actually link against crtbegin.o; the
|
|
linker won't look for a file to match a
|
|
wildcard. The wildcard also means that it
|
|
doesn't matter which directory crtbegin.o
|
|
is in. */
|
|
KEEP (*crtbegin*.o(.ctors))
|
|
/* We don't want to include the .ctor section from
|
|
from the crtend.o file until after the sorted ctors.
|
|
The .ctor section from the crtend file contains the
|
|
end of ctors marker and it must be last */
|
|
KEEP (*(EXCLUDE_FILE (*crtend*.o ) .ctors))
|
|
KEEP (*(SORT(.ctors.*)))
|
|
KEEP (*(.ctors))
|
|
}
|
|
.dtors :
|
|
{
|
|
KEEP (*crtbegin*.o(.dtors))
|
|
KEEP (*(EXCLUDE_FILE (*crtend*.o ) .dtors))
|
|
KEEP (*(SORT(.dtors.*)))
|
|
KEEP (*(.dtors))
|
|
}
|
|
.jcr : { KEEP (*(.jcr)) }
|
|
.data.rel.ro : { *(.data.rel.ro.local) *(.data.rel.ro*) }
|
|
.data :
|
|
{
|
|
_fdata = . ;
|
|
*(.data .data.* .gnu.linkonce.d.*)
|
|
KEEP (*(.gnu.linkonce.d.*personality*))
|
|
SORT(CONSTRUCTORS)
|
|
}
|
|
.data1 : { *(.data1) }
|
|
. = .;
|
|
_gp = ALIGN(16) + 0x7ff0;
|
|
.got : { *(.got.plt) *(.got) }
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata :
|
|
{
|
|
*(.sdata .sdata.* .gnu.linkonce.s.*)
|
|
}
|
|
.lit8 : { *(.lit8) }
|
|
.lit4 : { *(.lit4) }
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
__bss_start = .;
|
|
_fbss = .;
|
|
.sbss :
|
|
{
|
|
PROVIDE (__sbss_start = .);
|
|
PROVIDE (___sbss_start = .);
|
|
*(.dynsbss)
|
|
*(.sbss .sbss.* .gnu.linkonce.sb.*)
|
|
*(.scommon)
|
|
PROVIDE (__sbss_end = .);
|
|
PROVIDE (___sbss_end = .);
|
|
}
|
|
.bss :
|
|
{
|
|
*(.dynbss)
|
|
*(.bss .bss.* .gnu.linkonce.b.*)
|
|
*(COMMON)
|
|
/* Align here to ensure that the .bss section occupies space up to
|
|
_end. Align after .bss to ensure correct alignment even if the
|
|
.bss section disappears because there are no input sections. */
|
|
. = ALIGN(32 / 8);
|
|
}
|
|
. = ALIGN(32 / 8);
|
|
_end = .;
|
|
PROVIDE (end = .);
|
|
/* Stabs debugging sections. */
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
/* DWARF debug sections.
|
|
Symbols in the DWARF debugging sections are relative to the beginning
|
|
of the section so we begin them at 0. */
|
|
/* DWARF 1 */
|
|
.debug 0 : { *(.debug) }
|
|
.line 0 : { *(.line) }
|
|
/* GNU DWARF 1 extensions */
|
|
.debug_srcinfo 0 : { *(.debug_srcinfo) }
|
|
.debug_sfnames 0 : { *(.debug_sfnames) }
|
|
/* DWARF 1.1 and DWARF 2 */
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
/* DWARF 2 */
|
|
.debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_frame 0 : { *(.debug_frame) }
|
|
.debug_str 0 : { *(.debug_str) }
|
|
.debug_loc 0 : { *(.debug_loc) }
|
|
.debug_macinfo 0 : { *(.debug_macinfo) }
|
|
/* SGI/MIPS DWARF 2 extensions */
|
|
.debug_weaknames 0 : { *(.debug_weaknames) }
|
|
.debug_funcnames 0 : { *(.debug_funcnames) }
|
|
.debug_typenames 0 : { *(.debug_typenames) }
|
|
.debug_varnames 0 : { *(.debug_varnames) }
|
|
/DISCARD/ : { *(.comment) *(.pdr) }
|
|
/DISCARD/ : { *(.note.GNU-stack) }
|
|
}
|