mirror of
https://github.com/scp-fs2open/fs2open.github.com.git
synced 2026-11-07 16:18:19 -10:00
Shivansps
1d0dd687cd
* android build support * Update es_compatibility.h * Support reporting flags in android * include pref_path in json v2 * add vulkan headers * shaderc includes * remove headers * force use prebuilt vulkan * fix vulkan inverted screen * fix find sdl3 precompiled android * Update CMakeLists.txt * replace sdl2 android function names for sdl3 versions * change sdl includes in osapi * fix sdl3 includes, again * rename function to sdl3 name * remove unused definition * copy libshaderc_shared.so to output in android * do not look for vulkan-loader in android * revert changes to SDL2.cmake * add comment to vulkan pretransform setup * cleanup maxsize function * rename new android functions in osapi * android trap back button * Remove calculate_max_resize_max_size * touch ui opacity control * change opacity control to int * fix opacity slider * Corrected android working folder fallback and set borderless mode as default * Implement shared helper for JNI calls * Add version tag and sha256 to android prebuilt libs * vulkan android check eSuboptimal * An already requested rebuild also avoids redundant Android surface queries * add cache bool to cmakelist * set string ids
70 lines
2.4 KiB
CMake
70 lines
2.4 KiB
CMake
|
|
# We have precompiled libs for windows
|
|
IF (WIN32)
|
|
get_prebuilt_path(PREBUILT_PATH)
|
|
|
|
add_library(openal SHARED IMPORTED GLOBAL)
|
|
|
|
set(dll_name "${PREBUILT_PATH}/openal/bin/OpenAL32.dll")
|
|
|
|
set_target_properties(openal
|
|
PROPERTIES
|
|
IMPORTED_LOCATION "${dll_name}"
|
|
IMPORTED_IMPLIB "${PREBUILT_PATH}/openal/libs/${CMAKE_IMPORT_LIBRARY_PREFIX}OpenAL32${CMAKE_IMPORT_LIBRARY_SUFFIX}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${PREBUILT_PATH}/openal/include"
|
|
)
|
|
|
|
add_target_copy_files("${dll_name}")
|
|
ELSEIF(PLATFORM_MAC)
|
|
# use prebuilt openal-soft framework on Mac since the system version is
|
|
# deprecated and lacking features
|
|
get_prebuilt_path(PREBUILT_PATH)
|
|
|
|
add_library(openal INTERFACE)
|
|
unset(OPENAL_LIBRARY CACHE)
|
|
find_library(OPENAL_LIBRARY OpenAL PATHS "${PREBUILT_PATH}" NO_DEFAULT_PATH)
|
|
|
|
target_link_libraries(openal INTERFACE "${OPENAL_LIBRARY}")
|
|
target_include_directories(openal SYSTEM INTERFACE "${OPENAL_LIBRARY}/Headers")
|
|
|
|
add_target_copy_files("${OPENAL_LIBRARY}")
|
|
ELSE(WIN32)
|
|
option(OPENAL_USE_PRECOMPILED "Use precompiled version of OpenAL. If disabled the system libraries will be used." OFF)
|
|
|
|
set(USING_PREBUILT_LIBS FALSE)
|
|
set(OpenAL_ROOT_DIR)
|
|
|
|
include(util)
|
|
|
|
if(OPENAL_USE_PRECOMPILED)
|
|
get_prebuilt_path(PREBUILT_PATH)
|
|
set(OpenAL_ROOT_DIR "${PREBUILT_PATH}/openal")
|
|
set(USING_PREBUILT_LIBS TRUE)
|
|
else()
|
|
FIND_PACKAGE(OpenAL)
|
|
|
|
if(OpenAL_FOUND)
|
|
ADD_IMPORTED_LIB(openal "${OPENAL_INCLUDE_DIR}" "${OPENAL_LIBRARY}")
|
|
else()
|
|
message("OpenAL library could not be found. Using prebuilt library...")
|
|
|
|
get_prebuilt_path(PREBUILT_PATH)
|
|
set(OpenAL_ROOT_DIR "${PREBUILT_PATH}/openal")
|
|
set(USING_PREBUILT_LIBS TRUE)
|
|
endif()
|
|
endif()
|
|
|
|
if(USING_PREBUILT_LIBS)
|
|
message(STATUS "Using pre-built OpenAL library.")
|
|
|
|
unset(OpenAL_LOCATION CACHE)
|
|
find_library(OpenAL_LOCATION openal PATHS "${OpenAL_ROOT_DIR}/lib" NO_DEFAULT_PATH NO_CMAKE_FIND_ROOT_PATH)
|
|
|
|
get_filename_component(FULL_LIB_PATH "${OpenAL_LOCATION}" REALPATH)
|
|
ADD_IMPORTED_LIB(openal "${OpenAL_ROOT_DIR}/include" "${FULL_LIB_PATH}")
|
|
|
|
file(GLOB OpenAL_LIBS "${OpenAL_ROOT_DIR}/lib/libopenal*")
|
|
add_target_copy_files("${OpenAL_LIBS}")
|
|
endif()
|
|
ENDIF(WIN32)
|